mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
53226d9c87
Update piglit to latest git revision and update the branch name,
since the original one is no longer updated. Make sure the VK
tests are only enabled if VK is also enabled in PACKAGECONFIG,
and that this is opt-in, otherwise older systems fail to build.
Cherry picked from squashed commits:
eb3a8d4c7b ("piglit: upgrade to latest revision")
a27b06f73a ("piglit: upgrade to latest revision")
bb091bc0be ("piglit: upgrade to latest revision")
394746d1cb ("piglit: upgrade to latest revision")
5aec8cff94 ("piglit: upgrade to latest revision")
fc4c82773d ("piglit: fix reproducibility")
6fbec0f12a ("piglit: update to latest revision")
8d23a0d498 ("piglit: upgrade to latest revision")
5144d515fe ("piglit: upgrade to latest revision")
dd085bd577 ("piglit: upgrade to latest revision")
9ba6df1b2c ("piglit: upgrade to latest revision")
1ccd71eb3e ("piglit: upgrade to latest revision")
(From OE-Core rev: 65aa83e25059b29563a45eacdad8178bc7a07fe4)
Signed-off-by: Marek Vasut <marex@denx.de>
Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Cc: Anuj Mittal <anuj.mittal@intel.com>
Cc: Richard Purdie <richard.purdie@linuxfoundation.org>
Cc: Steve Sakoman <steve@sakoman.com>
Signed-off-by: Steve Sakoman <steve@sakoman.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
75 lines
3.2 KiB
BlitzBasic
75 lines
3.2 KiB
BlitzBasic
SUMMARY = "OpenGL driver testing framework"
|
|
DESCRIPTION = "Piglit is an open-source test suite for OpenGL and OpenCL \
|
|
implementations."
|
|
HOMEPAGE = "https://gitlab.freedesktop.org/mesa/piglit"
|
|
BUGTRACKER = "https://gitlab.freedesktop.org/mesa/piglit/-/issues"
|
|
LICENSE = "MIT & LGPLv2+ & GPLv3 & GPLv2+ & BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b2beded7103a3d8a442a2a0391d607b0"
|
|
|
|
SRC_URI = "git://gitlab.freedesktop.org/mesa/piglit.git;protocol=https;branch=main \
|
|
file://0001-cmake-install-bash-completions-in-the-right-place.patch \
|
|
file://0001-cmake-use-proper-WAYLAND_INCLUDE_DIRS-variable.patch \
|
|
file://0001-Add-a-missing-include-for-htobe32-definition.patch \
|
|
file://0001-generated_tests-gen_tcs-tes_input_tests.py-do-not-ha.patch \
|
|
file://0002-tests-util-piglit-shader.c-do-not-hardcode-build-pat.patch \
|
|
file://0001-serializer.py-make-.gz-files-reproducible.patch \
|
|
file://0001-framework-profile.py-make-test-lists-reproducible.patch \
|
|
file://0001-tests-shader.py-sort-the-file-list-before-working-on.patch \
|
|
"
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
|
|
SRCREV = "83bc56abf2686e2cd9024a152e121ca4aa524985"
|
|
# (when PV goes above 1.0 remove the trailing r)
|
|
PV = "1.0+gitr${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
|
|
X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
|
|
|
|
DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl"
|
|
|
|
inherit cmake pkgconfig python3native features_check bash-completion
|
|
|
|
# depends on virtual/libgl
|
|
REQUIRED_DISTRO_FEATURES += "opengl"
|
|
|
|
# The built scripts go into the temporary directory according to tempfile
|
|
# (typically /tmp) which can race if multiple builds happen on the same machine,
|
|
# so tell it to use a directory in ${B} to avoid overwriting.
|
|
export TEMP = "${B}/temp/"
|
|
do_compile[dirs] =+ "${B}/temp/"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
|
|
PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
|
|
PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
|
|
PACKAGECONFIG[vulkan] = "-DPIGLIT_BUILD_VK_TESTS=ON,-DPIGLIT_BUILD_VK_TESTS=OFF,vulkan-loader"
|
|
|
|
export PIGLIT_BUILD_DIR = "../../../../git"
|
|
|
|
do_configure_prepend() {
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
|
|
sed -i -e "/^#.*include <GL\/freeglut_ext.h>$/d" ${S}/src/piglit/glut_wrap.h
|
|
sed -i -e "/^#.*include.*<GL\/glut.h>$/d" ${S}/src/piglit/glut_wrap.h
|
|
fi
|
|
}
|
|
|
|
# Forcibly strip because Piglit is *huge*
|
|
OECMAKE_TARGET_INSTALL = "install/strip"
|
|
|
|
RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
|
|
python3-misc \
|
|
python3-unixadmin python3-xml python3-multiprocessing \
|
|
python3-six python3-shell python3-io \
|
|
python3-netserver bash \
|
|
"
|
|
|
|
INSANE_SKIP_${PN} += "dev-so already-stripped"
|
|
|
|
# As nothing builds against Piglit we don't need to have anything in the
|
|
# sysroot, especially when this is ~2GB of test suite
|
|
SYSROOT_DIRS_remove = "${libdir}"
|
|
|
|
# Can't be built with ccache
|
|
CCACHE_DISABLE = "1"
|