mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 18:53:13 +01:00
af06fafe79
The following line is added to fix cross-compilation issue in do_configure. EXTRA_OECONF += "gl_cv_func_strcasecmp_works=yes" The error message is as below: configure: error: cannot run test program while cross compiling (From OE-Core rev: c465fbbe4bfa90f7eed5e84c4149d656204481c8) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.4 KiB
BlitzBasic
42 lines
1.4 KiB
BlitzBasic
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
require diffutils.inc
|
|
|
|
SRC_URI = "${GNU_MIRROR}/diffutils/diffutils-${PV}.tar.xz \
|
|
file://run-ptest \
|
|
file://0001-Skip-strip-trailing-cr-test-case.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "7c8b7f9fc8609141fdea9cece85249d308624391ff61dedaf528fcb337727dfd"
|
|
|
|
EXTRA_OECONF += "ac_cv_path_PR_PROGRAM=${bindir}/pr --without-libsigsegv-prefix"
|
|
EXTRA_OECONF += "gl_cv_func_strcasecmp_works=yes"
|
|
|
|
# latest gnulib is no longer able to handle this - I dare not try to fix that maze of abstractions and generators
|
|
CFLAGS:mingw32 = " -DSA_RESTART=0"
|
|
|
|
EXTRA_OEMAKE:append:mingw32 = " LIBS='-lbcrypt'"
|
|
inherit ptest
|
|
|
|
RDEPENDS:${PN}-ptest += "make perl"
|
|
|
|
do_install_ptest() {
|
|
t=${D}${PTEST_PATH}
|
|
install -D ${S}/build-aux/test-driver $t/build-aux/test-driver
|
|
cp -r ${S}/tests $t/
|
|
install ${B}/tests/Makefile $t/tests/
|
|
sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
|
-e 's|^Makefile:|_Makefile:|' \
|
|
-e 's|bash|sh|' \
|
|
-e 's|^top_srcdir = \(.*\)|top_srcdir = ..\/|' \
|
|
-e 's|^srcdir = \(.*\)|srcdir = .|' \
|
|
-e 's|"`$(built_programs)`"|diff|' \
|
|
-e 's|gawk|awk|g' \
|
|
-i $t/tests/Makefile
|
|
}
|