mirror of
https://git.yoctoproject.org/poky
synced 2026-03-11 09:49:41 +01:00
cd4b8a8553
Fix handling of escape characters in regexs and hence fix python Deprecation warnings which will be problematic in python 3.8. Note that some show up as: """ meta/classes/package.bbclass:1293: DeprecationWarning: invalid escape sequence \. """ where the problem isn't on 1293 in package.bbclass but in some _prepend to a package.bbclass function in a different file like mesa.inc, often from do_package_split() calls. (From OE-Core rev: 4b1c0c7d5525fc4cea9e0f02ec54e92a6fbc6199) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
28 lines
921 B
BlitzBasic
28 lines
921 B
BlitzBasic
SUMMARY = "Optimised Inner Loop Runtime Compiler"
|
|
HOMEPAGE = "http://gstreamer.freedesktop.org/modules/orc.html"
|
|
LICENSE = "BSD-2-Clause & BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1400bd9d09e8af56b9ec982b3d85797e"
|
|
|
|
SRC_URI = "http://gstreamer.freedesktop.org/src/orc/orc-${PV}.tar.xz"
|
|
|
|
SRC_URI[md5sum] = "6b582ec4b3275c5efd51e3ae6406d445"
|
|
SRC_URI[sha256sum] = "bfcd7c6563b05672386c4eedfc4c0d4a0a12b4b4775b74ec6deb88fc2bcd83ce"
|
|
|
|
inherit autotools pkgconfig gtk-doc
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
PACKAGES =+ "orc-examples"
|
|
PACKAGES_DYNAMIC += "^liborc-.*"
|
|
FILES_orc-examples = "${libdir}/orc/*"
|
|
FILES_${PN} = "${bindir}/*"
|
|
|
|
python populate_packages_prepend () {
|
|
libdir = d.expand('${libdir}')
|
|
do_split_packages(d, libdir, r'^lib(.*)\.so\.*', 'lib%s', 'ORC %s library', extra_depends='', allow_links=True)
|
|
}
|
|
|
|
do_compile_prepend_class-native () {
|
|
sed -i -e 's#/tmp#.#g' ${S}/orc/orccodemem.c
|
|
}
|