mirror of
https://git.yoctoproject.org/poky
synced 2026-03-19 21:59:42 +01:00
ae85c4b9a6
Prelinking on x86-64 wasn't working out the box as it uses /lib and not /lib64 for libs. Prelink was refusing to link as the dynamic loader didn't match its idea of the right path. Passing in the --dyanmic-linker option avoids this. We can share code from image-mklibs so abstract that into a new class, linuxloader.bbclass. This does break prelinking of multilib images, I've opened a bug so we can loop back and fix that problem, the code would need to iterate the dynamic loaders (and setup ld.so.conf files for it). (From OE-Core rev: 7c3f2f61536cc8e0322087558cdcfe29ee2fac6d) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.6 KiB
Plaintext
55 lines
1.6 KiB
Plaintext
do_rootfs[depends] += "prelink-native:do_populate_sysroot"
|
|
|
|
IMAGE_PREPROCESS_COMMAND += "prelink_setup; prelink_image; "
|
|
|
|
python prelink_setup () {
|
|
oe.utils.write_ld_so_conf(d)
|
|
}
|
|
|
|
inherit linuxloader
|
|
|
|
prelink_image () {
|
|
# export PSEUDO_DEBUG=4
|
|
# /bin/env | /bin/grep PSEUDO
|
|
# echo "LD_LIBRARY_PATH=$LD_LIBRARY_PATH"
|
|
# echo "LD_PRELOAD=$LD_PRELOAD"
|
|
|
|
pre_prelink_size=`du -ks ${IMAGE_ROOTFS} | awk '{size = $1 ; print size }'`
|
|
echo "Size before prelinking $pre_prelink_size."
|
|
|
|
# We need a prelink conf on the filesystem, add one if it's missing
|
|
if [ ! -e ${IMAGE_ROOTFS}${sysconfdir}/prelink.conf ]; then
|
|
cp ${STAGING_DIR_NATIVE}${sysconfdir_native}/prelink.conf \
|
|
${IMAGE_ROOTFS}${sysconfdir}/prelink.conf
|
|
dummy_prelink_conf=true;
|
|
else
|
|
dummy_prelink_conf=false;
|
|
fi
|
|
|
|
# We need a ld.so.conf with pathnames in,prelink conf on the filesystem, add one if it's missing
|
|
ldsoconf=${IMAGE_ROOTFS}${sysconfdir}/ld.so.conf
|
|
if [ -e $ldsoconf ]; then
|
|
cp $ldsoconf $ldsoconf.prelink
|
|
fi
|
|
cat ${STAGING_DIR_TARGET}${sysconfdir}/ld.so.conf >> $ldsoconf
|
|
|
|
dynamic_loader=$(linuxloader)
|
|
|
|
# prelink!
|
|
${STAGING_DIR_NATIVE}${sbindir_native}/prelink --root ${IMAGE_ROOTFS} -amR -N -c ${sysconfdir}/prelink.conf --dynamic-linker $dynamic_loader
|
|
|
|
# Remove the prelink.conf if we had to add it.
|
|
if [ "$dummy_prelink_conf" = "true" ]; then
|
|
rm -f ${IMAGE_ROOTFS}${sysconfdir}/prelink.conf
|
|
fi
|
|
|
|
if [ -e $ldsoconf.prelink ]; then
|
|
mv $ldsoconf.prelink $ldsoconf
|
|
else
|
|
rm $ldsoconf
|
|
fi
|
|
|
|
pre_prelink_size=`du -ks ${IMAGE_ROOTFS} | awk '{size = $1 ; print size }'`
|
|
echo "Size after prelinking $pre_prelink_size."
|
|
}
|