mirror of
https://git.yoctoproject.org/poky
synced 2026-04-23 09:32:17 +02:00
6ce61b4357
The bluetooth support adds a bluez5 dependency (and,recursively, a lot of other stuff). Disable it by default to avoid having to build all of this when it is not needed. This decrease the number of tasks run for a core-image-minimal build by ~1000 (-21%). To re-enable bluetooth support in strace, add "bluez" to strace PACKAGECONFIG. For example, in local.conf: PACKAGECONFIG:append:pn-strace = " bluez" Fixes [YOCTO #15323] [RP: Tweaked to put a message about the change in the recipe] (From OE-Core rev: 5dbfeea1c90c4dab9291d27da5a7ed1706e2ac2e) Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Suggested-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
2.3 KiB
BlitzBasic
57 lines
2.3 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.io"
|
|
DESCRIPTION = "strace is a diagnostic, debugging and instructional userspace utility for Linux. It is used to monitor and tamper with interactions between processes and the Linux kernel, which include system calls, signal deliveries, and changes of process state."
|
|
SECTION = "console/utils"
|
|
LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=63c8c3eb5c71b4362edac1397f40bdc7"
|
|
|
|
SRC_URI = "https://strace.io/files/${PV}/strace-${PV}.tar.xz \
|
|
file://update-gawk-paths.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://ptest-spacesave.patch \
|
|
file://0001-strace-fix-reproducibilty-issues.patch \
|
|
file://skip-load.patch \
|
|
file://0001-configure-Use-autoconf-macro-to-detect-largefile-sup.patch \
|
|
file://0002-tests-Replace-off64_t-with-off_t.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "421b4186c06b705163e64dc85f271ebdcf67660af8667283147d5e859fc8a96c"
|
|
|
|
inherit autotools ptest
|
|
|
|
# Not yet ported to rv32
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
# bluez is not enabled by default due to build dependency creep in smaller builds
|
|
# like core-image-minimal leading to significantly more tasks being executed
|
|
PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
|
|
|
|
EXTRA_OECONF += "--enable-mpers=no --disable-gcc-Werror"
|
|
|
|
CFLAGS:append:libc-musl = " -Dsigcontext_struct=sigcontext"
|
|
|
|
TESTDIR = "tests"
|
|
PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
mkdir -p ${D}${PTEST_PATH}/build-aux
|
|
mkdir -p ${D}${PTEST_PATH}/src
|
|
install -m 755 ${S}/build-aux/test-driver ${D}${PTEST_PATH}/build-aux/
|
|
install -m 644 ${B}/src/config.h ${D}${PTEST_PATH}/src/
|
|
sed -i -e '/^src/s/strace.*[0-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += "make coreutils grep gawk sed"
|
|
|
|
RDEPENDS:${PN}-ptest:append:libc-glibc = "\
|
|
locale-base-en-us.iso-8859-1 \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native"
|