mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 09:32:11 +02:00
ec1ae11f78
The don't show up in CVE metrics anymore since they were either fixed upstream or recipe version was upgraded meanwhile. * bind CVE-2019-6470: cpe got corrected in nvd db * libxml2 CVE-2023-45322: version is now higher than NVD cpe * zlib CVE-2023-45853: version is now higher than NVD cpe * gcc CVE-2021-37322: version is now higher than NVD cpe * python3 * CVE-2007-4559: version is now higher than NVD cpe * CVE-2019-18348: version is now higher than NVD cpe * CVE-2020-15523: version is now higher than NVD cpe * CVE-2022-26488: version is now higher than NVD cpe * CVE-2015-20107: version is now higher than NVD cpe * CVE-2023-36632: version is now higher than NVD cpe * rust * CVE-2024-24576: NVD has no cpe, but we have newer version as fix * CVE-2024-43402: version is now higher than NVD cpe * cups CVE-2021-25317: version is now higher than NVD cpe * ghostscript CVE-2023-38559: version is now higher than NVD cpe * libtirpc CVE-2021-46828: version is now higher than NVD cpe * unzip CVE-2008-0888: version is now higher than NVD cpe * ffmpeg CVE-2023-39018: cpe got corrected in nvd db * libxslt CVE-2022-29824: version is now higher than NVD cpe * libyaml * CVE-2024-35325: CVE is now rejected in NVD DB * CVE-2024-35326: CVE is now rejected in NVD DB * CVE-2024-35328: CVE is now rejected in NVD DB Also add comment for iputils regarding reports for FKIE/NVD2. Also remove some trailing spaces in python recipe. (From OE-Core rev: 73ee9789183aa95072af2b51ac9e08203f4e33f9) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
2.2 KiB
BlitzBasic
58 lines
2.2 KiB
BlitzBasic
SUMMARY = "Network monitoring tools"
|
|
DESCRIPTION = "Utilities for the IP protocol, including \
|
|
tracepath, tracepath6, ping, ping6 and arping."
|
|
HOMEPAGE = "https://github.com/iputils/iputils"
|
|
SECTION = "console/network"
|
|
|
|
LICENSE = "BSD-3-Clause & GPL-2.0-or-later"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=627cc07ec86a45951d43e30658bbd819"
|
|
|
|
SRC_URI = "git://github.com/iputils/iputils;branch=master;protocol=https \
|
|
"
|
|
SRCREV = "6e1cb146547eb6fbb127ffc8397a9241be0d33c2"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>20\d+)"
|
|
|
|
# these currently don't show up in CVE metrics for FKIE (as 2000 is not covered by it), but they would show for NVD2
|
|
CVE_STATUS[CVE-2000-1213] = "fixed-version: Fixed in 2000-10-10, but the versioning of iputils breaks the version order."
|
|
CVE_STATUS[CVE-2000-1214] = "fixed-version: Fixed in 2000-10-10, but the versioning of iputils breaks the version order."
|
|
|
|
PACKAGECONFIG ??= "libcap"
|
|
PACKAGECONFIG[libcap] = "-DUSE_CAP=true, -DUSE_CAP=false -DNO_SETCAP_OR_SUID=true, libcap libcap-native"
|
|
PACKAGECONFIG[libidn] = "-DUSE_IDN=true, -DUSE_IDN=false, libidn2"
|
|
PACKAGECONFIG[gettext] = "-DUSE_GETTEXT=true, -DUSE_GETTEXT=false, gettext"
|
|
PACKAGECONFIG[docs] = "-DBUILD_HTML_MANS=true -DBUILD_MANS=true,-DBUILD_HTML_MANS=false -DBUILD_MANS=false, libxslt"
|
|
|
|
inherit meson update-alternatives pkgconfig
|
|
|
|
EXTRA_OEMESON += "--prefix=${root_prefix}/ -DSKIP_TESTS=true"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE:${PN}-ping = "ping"
|
|
ALTERNATIVE_LINK_NAME[ping] = "${base_bindir}/ping"
|
|
|
|
ALTERNATIVE:${PN}-ping6 = "ping6"
|
|
ALTERNATIVE_LINK_NAME[ping6] = "${base_bindir}/ping6"
|
|
|
|
SPLITPKGS = "${PN}-ping ${PN}-arping ${PN}-tracepath ${PN}-clockdiff \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', '${PN}-ping6', '', d)}"
|
|
PACKAGES += "${SPLITPKGS}"
|
|
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
RDEPENDS:${PN} += "${SPLITPKGS}"
|
|
|
|
FILES:${PN} = ""
|
|
FILES:${PN}-ping = "${base_bindir}/ping.${BPN}"
|
|
FILES:${PN}-ping6 = "${base_bindir}/ping6.${BPN}"
|
|
FILES:${PN}-arping = "${base_bindir}/arping"
|
|
FILES:${PN}-tracepath = "${base_bindir}/tracepath"
|
|
FILES:${PN}-clockdiff = "${base_bindir}/clockdiff"
|
|
|
|
do_install:append() {
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', 'true', 'false', d)}; then
|
|
ln -sf ping ${D}/${base_bindir}/ping6
|
|
fi
|
|
}
|