mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
e605e2d048
When we have hard-float ABI enabled, certain tools e.g. llvm/clang expects the hf version of tuples for crt files from libgcc, therefore create a symlink to help the cause. This makes clang work with hard-float defaults on target (From OE-Core rev: f58cf0d0ff05636a70330c54f7e537f9480674c4) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.6 KiB
PHP
50 lines
1.6 KiB
PHP
require libgcc-common.inc
|
|
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++ virtual/${MLPREFIX}libc"
|
|
|
|
do_install_append_class-target () {
|
|
if [ "${TCLIBC}" != "glibc" ]; then
|
|
case "${TARGET_OS}" in
|
|
"linux-musl" | "linux-*spe") extra_target_os="linux";;
|
|
"linux-musleabi") extra_target_os="linux-gnueabi";;
|
|
*) extra_target_os="linux";;
|
|
esac
|
|
ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
|
|
fi
|
|
if [ -n "${@ bb.utils.contains('TUNE_CCARGS_MFLOAT', 'hard', 'hf', '', d)}" ]; then
|
|
case "${TARGET_OS}" in
|
|
"linux-musleabi") extra_target_os="linux-musleabihf";;
|
|
"linux-gnueabi") extra_target_os="linux-gnueabihf";;
|
|
esac
|
|
ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
|
|
fi
|
|
}
|
|
|
|
PACKAGES = "\
|
|
${PN} \
|
|
${PN}-dev \
|
|
${PN}-dbg \
|
|
"
|
|
|
|
# All libgcc source is marked with the exception.
|
|
#
|
|
LICENSE_${PN} = "GPL-3.0-with-GCC-exception"
|
|
LICENSE_${PN}-dev = "GPL-3.0-with-GCC-exception"
|
|
LICENSE_${PN}-dbg = "GPL-3.0-with-GCC-exception"
|
|
|
|
|
|
FILES_${PN}-dev = "\
|
|
${base_libdir}/libgcc*.so \
|
|
${@oe.utils.conditional('BASETARGET_SYS', '${TARGET_SYS}', '', '${libdir}/${BASETARGET_SYS}', d)} \
|
|
${libdir}/${TARGET_SYS}/${BINV}* \
|
|
${libdir}/${TARGET_ARCH}${TARGET_VENDOR}* \
|
|
"
|
|
|
|
do_package[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
|
|
INSANE_SKIP_${PN}-dev = "staticdev"
|
|
|