mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
fa809fd073
Drop patches that have been upstreamed. Refresh others. This version dropped extra_deps.lst from the tarball [1] and that leads to build failures. Restore it in do_configure for now. [1] https://git.savannah.gnu.org/cgit/grub.git/commit/?id=b835601c7639ed1890f2d3db91900a8506011a8e (From OE-Core rev: 7c8e1e48075f7f54aec9d295605c982f440be5d5) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.1 KiB
BlitzBasic
42 lines
1.1 KiB
BlitzBasic
require grub2.inc
|
|
|
|
RDEPENDS:${PN}-common += "${PN}-editenv"
|
|
RDEPENDS:${PN} += "${PN}-common"
|
|
RDEPENDS:${PN}:class-native = ""
|
|
|
|
RPROVIDES:${PN}-editenv += "${PN}-efi-editenv"
|
|
|
|
PROVIDES:append:class-native = " grub-efi-native"
|
|
|
|
PACKAGES =+ "${PN}-editenv ${PN}-common"
|
|
FILES:${PN}-editenv = "${bindir}/grub-editenv"
|
|
FILES:${PN}-common = " \
|
|
${bindir} \
|
|
${sysconfdir} \
|
|
${sbindir} \
|
|
${datadir}/grub \
|
|
"
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
|
|
do_install:append () {
|
|
# Avoid conflicts with the EFI package for systems such as arm64 where we
|
|
# need to build grub and grub-efi but only EFI is supported by removing EFI
|
|
# from this package.
|
|
rm -rf ${D}${libdir}/grub/*-efi/
|
|
rmdir --ignore-fail-on-non-empty ${D}${libdir}/grub ${D}${libdir}
|
|
|
|
install -d ${D}${sysconfdir}/grub.d
|
|
# Remove build host references...
|
|
find "${D}" -name modinfo.sh -type f -exec \
|
|
sed -i \
|
|
-e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
{} +
|
|
}
|
|
|
|
INSANE_SKIP:${PN} = "arch"
|
|
INSANE_SKIP:${PN}-dbg = "arch"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|