mirror of
https://git.yoctoproject.org/poky
synced 2026-03-14 19:29:41 +01:00
463172affb
This is CVE for example tool contrib/untgz. This is not compiled in Yocto zlib recipe. This CVE has controversial CVSS3 score of 9.8. (From OE-Core rev: b00a1990237d473971076c4f92a1060911b8b323) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Antonin Godard <antonin.godard@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit b0592c51b6ad038d737d2f6b30977bd0c5c50058) Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Paul Barker <paul@pbarker.dev> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.5 KiB
BlitzBasic
53 lines
1.5 KiB
BlitzBasic
SUMMARY = "Zlib Compression Library"
|
|
DESCRIPTION = "Zlib is a general-purpose, patent-free, lossless data compression \
|
|
library which is used by many different programs."
|
|
HOMEPAGE = "http://zlib.net/"
|
|
SECTION = "libs"
|
|
LICENSE = "Zlib"
|
|
LIC_FILES_CHKSUM = "file://zlib.h;beginline=6;endline=23;md5=5377232268e952e9ef63bc555f7aa6c0"
|
|
|
|
# The source tarball needs to be .gz as only the .gz ends up in fossils/
|
|
SRC_URI = "https://zlib.net/${BP}.tar.gz \
|
|
file://0001-configure-Pass-LDFLAGS-to-link-tests.patch \
|
|
file://run-ptest \
|
|
"
|
|
UPSTREAM_CHECK_URI = "http://zlib.net/"
|
|
|
|
SRC_URI[sha256sum] = "9a93b2b7dfdac77ceba5a558a580e74667dd6fede4585b91eefb60f03b72df23"
|
|
|
|
# When a new release is made the previous release is moved to fossils/, so add this
|
|
# to PREMIRRORS so it is also searched automatically.
|
|
PREMIRRORS:append = " https://zlib.net/ https://zlib.net/fossils/"
|
|
|
|
CFLAGS += "-D_REENTRANT"
|
|
|
|
RDEPENDS:${PN}-ptest += "make"
|
|
|
|
inherit ptest
|
|
|
|
B = "${WORKDIR}/build"
|
|
|
|
do_configure() {
|
|
LDCONFIG=true ${S}/configure --prefix=${prefix} --shared --libdir=${libdir} --uname=GNU
|
|
}
|
|
do_configure[cleandirs] += "${B}"
|
|
|
|
do_compile() {
|
|
oe_runmake shared
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install ${B}/examplesh ${D}${PTEST_PATH}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Adding 'CVE_PRODUCT' to avoid false detection of CVEs
|
|
CVE_PRODUCT = "zlib:zlib gnu:zlib"
|
|
|
|
CVE_STATUS[CVE-2026-22184] = "not-applicable-config: vulnerable file is not compiled"
|