mirror of
https://git.yoctoproject.org/poky
synced 2026-03-11 01:39:40 +01:00
d13cc87bea
avoid_parallel_tests.patch refreshed for 6.7 Changelog: =========== * Feature: support for setting TCP data split * Fix: fix new gcc14 warning * Fix: fix SFF-8472 transceiver module identification (-m) * Misc: code cleanup (From OE-Core rev: 0bce08e38b496771a54d22ba494b3e818f186ef8) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.4 KiB
BlitzBasic
38 lines
1.4 KiB
BlitzBasic
SUMMARY = "Display or change ethernet card settings"
|
|
DESCRIPTION = "A small utility for examining and tuning the settings of your ethernet-based network interfaces."
|
|
HOMEPAGE = "http://www.kernel.org/pub/software/network/ethtool/"
|
|
SECTION = "console/network"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://ethtool.c;beginline=4;endline=17;md5=c19b30548c582577fc6b443626fc1216"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/network/ethtool/ethtool-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://avoid_parallel_tests.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "ace0e95a03b38208af4ebacb415244568ace44c5d5a279ea434844f900179c75"
|
|
|
|
UPSTREAM_CHECK_URI = "https://www.kernel.org/pub/software/network/ethtool/"
|
|
|
|
inherit autotools ptest bash-completion pkgconfig
|
|
|
|
RDEPENDS:${PN}-ptest += "make bash"
|
|
|
|
PACKAGECONFIG ?= "netlink"
|
|
PACKAGECONFIG[netlink] = "--enable-netlink,--disable-netlink,libmnl,"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp ${B}/Makefile ${D}${PTEST_PATH}
|
|
install ${B}/test-cmdline ${D}${PTEST_PATH}
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'netlink', 'false', 'true', d)}; then
|
|
install ${B}/test-features ${D}${PTEST_PATH}
|
|
fi
|
|
install ${B}/ethtool ${D}${PTEST_PATH}/ethtool
|
|
sed -i 's/^Makefile/_Makefile/' ${D}${PTEST_PATH}/Makefile
|
|
}
|