mirror of
https://git.yoctoproject.org/poky
synced 2026-03-10 01:09:40 +01:00
53e39c1063
Changelog: =========== * [Quan quan Cao]: sar/sadc: Add new metrics pgprom/s and pgdem/s. * sar: Remove %vmeff metric. * sadf: Update various output formats to take into account metrics that have been added or removed. * Update DTD and XSD documents. * Update sar manual page. * sar: Add a cron entry and a new systemd service and timer to rotate daily data file at midnight. * Option -V with sysstat commands also displays environment contents. * [Sam Morris]: Use correct encoding to produce hyphen-minus when rendering man pages. * Add UMASK variable definition to sysstat(5) manual page. * Update non regression tests. * Add --getenv option to commands that didn't have it. * Update README file for Debian-based distros. * Update link to my personal web page in README and manual pages. * NLS: Translations updated. (From OE-Core rev: cebecc455d5e4ef84669d05707244be1cca8c271) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
81 lines
2.7 KiB
BlitzBasic
81 lines
2.7 KiB
BlitzBasic
SUMMARY = "System performance tools"
|
|
DESCRIPTION = "The sysstat utilities are a collection of performance monitoring tools for Linux."
|
|
HOMEPAGE = "https://sysstat.github.io/"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
SECTION = "console/utils"
|
|
|
|
SRC_URI = "git://github.com/sysstat/sysstat.git;protocol=https;branch=master \
|
|
file://99_sysstat \
|
|
file://sysstat.service \
|
|
file://0001-configure.in-remove-check-for-chkconfig.patch \
|
|
"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a23a74b3f4caf9616230789d94217acb"
|
|
|
|
SRCREV = "2d7682f26f42cef9127b123e319349b330c4ab8f"
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS += "base-passwd"
|
|
|
|
# autotools-brokensep as this package doesn't use automake
|
|
inherit autotools-brokensep gettext systemd
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[lm-sensors] = "--enable-sensors,--disable-sensors,lmsensors,lmsensors-libsensors"
|
|
PACKAGECONFIG[cron] = "--enable-install-cron --enable-copy-only,--disable-install-cron --disable-copy-only"
|
|
PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_system_unitdir}"
|
|
|
|
EXTRA_OECONF += "--disable-stripping"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "sysstat.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
do_configure:prepend() {
|
|
export sa_lib_dir=${libexecdir}/sa
|
|
}
|
|
|
|
do_install() {
|
|
autotools_do_install
|
|
|
|
# Don't version the documentation
|
|
mv ${D}${docdir}/${BP} ${D}${docdir}/${BPN}
|
|
|
|
# don't install /var/log/sa when populating rootfs. Do it through volatile
|
|
rm -rf ${D}/var
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
|
|
install -d ${D}/etc/default/volatiles
|
|
install -m 0644 ${WORKDIR}/99_sysstat ${D}/etc/default/volatiles
|
|
fi
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -d ${D}${nonarch_libdir}/tmpfiles.d
|
|
echo "d ${localstatedir}/log/sa - - - -" \
|
|
> ${D}${nonarch_libdir}/tmpfiles.d/sysstat.conf
|
|
|
|
# Unless both cron and systemd are enabled, install our own
|
|
# systemd unit file. Otherwise the package will install one.
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'cron systemd', 'false', 'true', d)}; then
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${WORKDIR}/sysstat.service ${D}${systemd_system_unitdir}
|
|
sed -i -e 's#@LIBEXECDIR@#${libexecdir}#g' ${D}${systemd_system_unitdir}/sysstat.service
|
|
fi
|
|
fi
|
|
}
|
|
|
|
pkg_postinst:${PN} () {
|
|
if [ ! -n "$D" ]; then
|
|
if [ -e /etc/init.d/populate-volatile.sh ]; then
|
|
/etc/init.d/populate-volatile.sh update
|
|
fi
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${systemd_system_unitdir} \
|
|
${nonarch_base_libdir}/systemd \
|
|
${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|