mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 03:32:12 +02:00
9da30a8753
The zlib crate in rust uses libz.a which comes from the zlib-native build. Some distros like alma9, fedora etc. do not have PIE enabled by default for system compiler. This leads to target-rust-ccld linking error for cargo-native as (line no 22936): error: linking with `/home/pokybuild/yocto-worker/qemuarm64/build/build/tmp/work/x86_64-linux/cargo-native/1.79.0/wrapper/target-rust-ccld` failed: exit status: 1 https://autobuilder.yoctoproject.org/typhoon/#/builders/42/builds/9385/steps/13/logs/stdio Hence, enable PIE option to CFLAGS for native builds. (From OE-Core rev: 7146d260f655fa924461333c8c2944ebb93b2b3c) Signed-off-by: Yash Shinde <Yash.Shinde@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.5 KiB
BlitzBasic
53 lines
1.5 KiB
BlitzBasic
SUMMARY = "Zlib Compression Library"
|
|
DESCRIPTION = "Zlib is a general-purpose, patent-free, lossless data compression \
|
|
library which is used by many different programs."
|
|
HOMEPAGE = "http://zlib.net/"
|
|
SECTION = "libs"
|
|
LICENSE = "Zlib"
|
|
LIC_FILES_CHKSUM = "file://zlib.h;beginline=6;endline=23;md5=5377232268e952e9ef63bc555f7aa6c0"
|
|
|
|
# The source tarball needs to be .gz as only the .gz ends up in fossils/
|
|
SRC_URI = "https://zlib.net/${BP}.tar.gz \
|
|
file://0001-configure-Pass-LDFLAGS-to-link-tests.patch \
|
|
file://run-ptest \
|
|
"
|
|
UPSTREAM_CHECK_URI = "http://zlib.net/"
|
|
|
|
SRC_URI[sha256sum] = "9a93b2b7dfdac77ceba5a558a580e74667dd6fede4585b91eefb60f03b72df23"
|
|
|
|
# When a new release is made the previous release is moved to fossils/, so add this
|
|
# to PREMIRRORS so it is also searched automatically.
|
|
PREMIRRORS:append = " https://zlib.net/ https://zlib.net/fossils/"
|
|
|
|
CFLAGS += "-D_REENTRANT -fPIE"
|
|
|
|
RDEPENDS:${PN}-ptest += "make"
|
|
|
|
inherit ptest
|
|
|
|
B = "${WORKDIR}/build"
|
|
|
|
do_configure() {
|
|
LDCONFIG=true ${S}/configure --prefix=${prefix} --shared --libdir=${libdir} --uname=GNU
|
|
}
|
|
do_configure[cleandirs] += "${B}"
|
|
|
|
do_compile() {
|
|
oe_runmake shared
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install ${B}/examplesh ${D}${PTEST_PATH}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
CVE_STATUS[CVE-2023-45853] = "not-applicable-config: we don't build minizip"
|
|
|
|
# Adding 'CVE_PRODUCT' to avoid false detection of CVEs
|
|
CVE_PRODUCT = "zlib:zlib gnu:zlib"
|