mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
ccf38a6bcf
avoid_parallel_tests.patch refreshed for 6.10 Changelog: ========== * Feature: suport for PoE in PSE (--show-pse and --set-pse) * Feature: add statistics support to tsinfo (-T) * Feature: add JSON output to base command (no option) * Feature: add JSON output to EEE info (--show-eee) * Fix: qsfp: better handling on page 03h read failure (-m) * Fix: handle zero arguments for module eeprom dump (-m) * Fix: check for missing arguments in do_srxfh() (-X) * Misc: compiler warnings in "make check" * Misc: more descriptive error when JSON output is not available (From OE-Core rev: ffcffccfec29c18c1b97394d7d707f4b8dd5362e) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.4 KiB
BlitzBasic
38 lines
1.4 KiB
BlitzBasic
SUMMARY = "Display or change ethernet card settings"
|
|
DESCRIPTION = "A small utility for examining and tuning the settings of your ethernet-based network interfaces."
|
|
HOMEPAGE = "http://www.kernel.org/pub/software/network/ethtool/"
|
|
SECTION = "console/network"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://ethtool.c;beginline=4;endline=17;md5=c19b30548c582577fc6b443626fc1216"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/network/ethtool/ethtool-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://avoid_parallel_tests.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "2b266c45c0fe00e5f5b462ee4e795879fa4247003bf73c5a07a2279d801be058"
|
|
|
|
UPSTREAM_CHECK_URI = "https://www.kernel.org/pub/software/network/ethtool/"
|
|
|
|
inherit autotools ptest bash-completion pkgconfig
|
|
|
|
RDEPENDS:${PN}-ptest += "make bash"
|
|
|
|
PACKAGECONFIG ?= "netlink"
|
|
PACKAGECONFIG[netlink] = "--enable-netlink,--disable-netlink,libmnl,"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp ${B}/Makefile ${D}${PTEST_PATH}
|
|
install ${B}/test-cmdline ${D}${PTEST_PATH}
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'netlink', 'false', 'true', d)}; then
|
|
install ${B}/test-features ${D}${PTEST_PATH}
|
|
fi
|
|
install ${B}/ethtool ${D}${PTEST_PATH}/ethtool
|
|
sed -i 's/^Makefile/_Makefile/' ${D}${PTEST_PATH}/Makefile
|
|
}
|