mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 21:32:12 +02:00
f17139fb5c
Changelog: ========== * sar/sadf: [A_NET_ETCP]: Rename retrans/s field to retrseg/s because it was already used in A_NET_NFS report. * sadf: SVG: Fix oversized SVG canvas height. * sadf: Don't cap SVG graph output at 100%. * sadf: A_NET_SOFT: Don't display graphs for offline CPU. * sadf: SVG: Don't ignore other views when one has to be skipped. * sadf: Make sure structures will be alloacated for every installed CPU. * sadf: Define MIN_CANVAS_HEIGHT constant. * sar: Display min/max values only when available. * Define macros for CPU manipulation. * SREALLOC() macro: Make sure size is not zero. * Fix a warning given by gcc v13 with -fanalyzer option. * [Eli Schwartz]: configure.ac: fix erroneous bashisms. * sar manual page updated. * DTD and XSD documents updated. * Year updated in copyright messages. * Other cosmetic changes in code. * FAQ and README files updated. * Non regression tests updated. New tests added. (From OE-Core rev: e3382192725303a9bf55e10fa33379e7b54ed1b2) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
81 lines
2.7 KiB
BlitzBasic
81 lines
2.7 KiB
BlitzBasic
SUMMARY = "System performance tools"
|
|
DESCRIPTION = "The sysstat utilities are a collection of performance monitoring tools for Linux."
|
|
HOMEPAGE = "https://sysstat.github.io/"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
SECTION = "console/utils"
|
|
|
|
SRC_URI = "git://github.com/sysstat/sysstat.git;protocol=https;branch=master \
|
|
file://99_sysstat \
|
|
file://sysstat.service \
|
|
file://0001-configure.in-remove-check-for-chkconfig.patch \
|
|
"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a23a74b3f4caf9616230789d94217acb"
|
|
|
|
SRCREV = "3e3ec9b2c69940503723e3c2ffc1965a8a3484e3"
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS += "base-passwd"
|
|
|
|
# autotools-brokensep as this package doesn't use automake
|
|
inherit autotools-brokensep gettext systemd
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[lm-sensors] = "--enable-sensors,--disable-sensors,lmsensors,lmsensors-libsensors"
|
|
PACKAGECONFIG[cron] = "--enable-install-cron --enable-copy-only,--disable-install-cron --disable-copy-only"
|
|
PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_system_unitdir}"
|
|
|
|
EXTRA_OECONF += "--disable-stripping"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "sysstat.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
do_configure:prepend() {
|
|
export sa_lib_dir=${libexecdir}/sa
|
|
}
|
|
|
|
do_install() {
|
|
autotools_do_install
|
|
|
|
# Don't version the documentation
|
|
mv ${D}${docdir}/${BP} ${D}${docdir}/${BPN}
|
|
|
|
# don't install /var/log/sa when populating rootfs. Do it through volatile
|
|
rm -rf ${D}/var
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
|
|
install -d ${D}/etc/default/volatiles
|
|
install -m 0644 ${UNPACKDIR}/99_sysstat ${D}/etc/default/volatiles
|
|
fi
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -d ${D}${nonarch_libdir}/tmpfiles.d
|
|
echo "d ${localstatedir}/log/sa - - - -" \
|
|
> ${D}${nonarch_libdir}/tmpfiles.d/sysstat.conf
|
|
|
|
# Unless both cron and systemd are enabled, install our own
|
|
# systemd unit file. Otherwise the package will install one.
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'cron systemd', 'false', 'true', d)}; then
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${UNPACKDIR}/sysstat.service ${D}${systemd_system_unitdir}
|
|
sed -i -e 's#@LIBEXECDIR@#${libexecdir}#g' ${D}${systemd_system_unitdir}/sysstat.service
|
|
fi
|
|
fi
|
|
}
|
|
|
|
pkg_postinst:${PN} () {
|
|
if [ ! -n "$D" ]; then
|
|
if [ -e /etc/init.d/populate-volatile.sh ]; then
|
|
/etc/init.d/populate-volatile.sh update
|
|
fi
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${systemd_system_unitdir} \
|
|
${nonarch_base_libdir}/systemd \
|
|
${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|