mirror of
https://git.yoctoproject.org/poky
synced 2026-05-04 22:39:49 +02:00
8fe4344e74
These recipes use gnulib which needs this change to use gets when its defined and not otherwise. Until that change goes into gnulib and then all these package upgrade gnulib in their sourcebase we patch them (From OE-Core rev: b955f1a7bc716055c78ed575eccac6f611dc2395) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Resolved merge conflicts with denzil branch and backported gnutls patch. Signed-off-by: Scott Garman <scott.a.garman@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
105 lines
4.9 KiB
BlitzBasic
105 lines
4.9 KiB
BlitzBasic
SUMMARY = "Utilities and libraries for producing multi-lingual messages."
|
|
DESCRIPTION = "Gettext offers to programmers, translators, and even users, a well integrated set of tools and documentation. Specifically, the GNU `gettext' utilities are a set of tools that provides a framework to help other GNU packages produce multi-lingual messages. These tools include a set of conventions about how programs should be written to support message catalogs, a directory and file naming organization for the message catalogs themselves, a runtime library supporting the retrieval of translated messages, and a few stand-alone programs to massage in various ways the sets of translatable strings, or already translated strings."
|
|
HOMEPAGE = "http://www.gnu.org/software/gettext/gettext.html"
|
|
SECTION = "libs"
|
|
LICENSE = "GPLv3+ & LGPL-2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
PR = "r13"
|
|
DEPENDS = "libxml2-native gettext-native virtual/libiconv ncurses expat"
|
|
DEPENDS_virtclass-native = "libxml2-native gettext-minimal-native"
|
|
PROVIDES = "virtual/libintl virtual/gettext"
|
|
PROVIDES_virtclass-native = "virtual/gettext-native"
|
|
CONFLICTS_${PN} = "proxy-libintl"
|
|
SRC_URI = "${GNU_MIRROR}/gettext/gettext-${PV}.tar.gz \
|
|
file://parallel.patch \
|
|
file://remove_gets.patch \
|
|
"
|
|
|
|
SRC_URI_append_libc-uclibc = " file://wchar-uclibc.patch \
|
|
file://gnulib-uclibc-sched_param-def.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "3dd55b952826d2b32f51308f2f91aa89"
|
|
SRC_URI[sha256sum] = "93ac71a7afa5b70c1b1032516663658c51e653087f42a3fc8044752c026443e9"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF += "--without-lispdir \
|
|
--disable-csharp \
|
|
--disable-libasprintf \
|
|
--disable-java \
|
|
--disable-native-java \
|
|
--disable-openmp \
|
|
--with-included-glib \
|
|
--with-libncurses-prefix=${STAGING_LIBDIR}/.. \
|
|
--without-emacs \
|
|
--without-cvs \
|
|
--without-git \
|
|
--with-included-libxml \
|
|
--with-included-libcroco \
|
|
--with-included-libunistring \
|
|
"
|
|
|
|
acpaths = '-I ${S}/gettext-runtime/m4 \
|
|
-I ${S}/gettext-tools/m4'
|
|
|
|
|
|
# these lack the .x behind the .so, but shouldn't be in the -dev package
|
|
# Otherwise you get the following results:
|
|
# 7.4M glibc/images/ep93xx/Angstrom-console-image-glibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
|
|
# 25M uclibc/images/ep93xx/Angstrom-console-image-uclibc-ipk-2008.1-test-20080104-ep93xx.rootfs.tar.gz
|
|
# because gettext depends on gettext-dev, which pulls in more -dev packages:
|
|
# 15228 KiB /ep93xx/libstdc++-dev_4.2.2-r2_ep93xx.ipk
|
|
# 1300 KiB /ep93xx/uclibc-dev_0.9.29-r8_ep93xx.ipk
|
|
# 140 KiB /armv4t/gettext-dev_0.14.1-r6_armv4t.ipk
|
|
# 4 KiB /ep93xx/libgcc-s-dev_4.2.2-r2_ep93xx.ipk
|
|
|
|
PACKAGES =+ "libgettextlib libgettextsrc"
|
|
FILES_libgettextlib = "${libdir}/libgettextlib-*.so*"
|
|
FILES_libgettextsrc = "${libdir}/libgettextsrc-*.so*"
|
|
|
|
PACKAGES =+ "gettext-runtime gettext-runtime-dev gettext-runtime-doc"
|
|
|
|
FILES_gettext-runtime = "${bindir}/gettext \
|
|
${bindir}/ngettext \
|
|
${bindir}/envsubst \
|
|
${bindir}/gettext.sh \
|
|
${libdir}/libasprintf.so* \
|
|
${libdir}/GNU.Gettext.dll \
|
|
"
|
|
FILES_gettext-runtime_append_libc-uclibc = " ${libdir}/libintl.so.* \
|
|
${libdir}/charset.alias \
|
|
"
|
|
FILES_gettext-runtime-dev += "${libdir}/libasprintf.a \
|
|
${includedir}/autosprintf.h \
|
|
"
|
|
FILES_gettext-runtime-dev_append_libc-uclibc = " ${libdir}/libintl.a \
|
|
${libdir}/libintl.so \
|
|
${includedir}/libintl.h \
|
|
"
|
|
FILES_gettext-runtime-doc = "${mandir}/man1/gettext.* \
|
|
${mandir}/man1/ngettext.* \
|
|
${mandir}/man1/envsubst.* \
|
|
${mandir}/man1/.* \
|
|
${mandir}/man3/* \
|
|
${docdir}/gettext/gettext.* \
|
|
${docdir}/gettext/ngettext.* \
|
|
${docdir}/gettext/envsubst.* \
|
|
${docdir}/gettext/*.3.html \
|
|
${datadir}/gettext/ABOUT-NLS \
|
|
${docdir}/gettext/csharpdoc/* \
|
|
${docdir}/libasprintf/autosprintf.html \
|
|
${infodir}/autosprintf.info \
|
|
"
|
|
|
|
do_install_append() {
|
|
rm -f ${D}${libdir}/preloadable_libintl.so
|
|
}
|
|
|
|
do_install_append_virtclass-native () {
|
|
rm ${D}${datadir}/aclocal/*
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|