mirror of
https://git.yoctoproject.org/poky
synced 2026-04-20 00:32:13 +02:00
90e0a0f7f4
The idea of the base class dependency is to say "yes, I need a C cross compiler" and this was never meant to be gcc specific. Looking at the codebase, whilst we code triplets into this, it does overcomplicate things as there are only ever limited, "target", "sdk" and the class extended versions like mutlilib. After much thought, we can simplify this to virtual/cross-cc and virtual/nativesdk-cross-cc. This lets us remove the "gcc" specific element as well as removing the over complicated triplet usage. At the same time, change the much less widely used "g++" variant to "c++" for similar reasons and remove the triplet from virtual/XXX-binutils too. Backwards compatibility mappings could be left but are just going to confuse things in future so we'll just require users to update. This simplification, whilst disruptive for any toolchain focused layers, will make improved toolchain selection in the future much easier. Since we no longer have overlapping variables, some code for that can just be removed. The class extension code does need to start remapping some variables but not the crosssdk target recipe names. This patch is in two pieces, this one handles the renaming with the functional changes separate in a second for easier review even if this breaks bisection. (From OE-Core rev: 4ccc3bc8266c327bcc18c9a3faf7536210dfb9f0) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
87 lines
3.2 KiB
BlitzBasic
87 lines
3.2 KiB
BlitzBasic
# NOTE: This recipe cannot have -cross- in the file name because it triggers
|
|
# the cross build detection in sstate which causes it to use the wrong
|
|
# architecture
|
|
require binutils.inc
|
|
require binutils-${PV}.inc
|
|
|
|
BPN = "binutils"
|
|
|
|
DEPENDS += "dejagnu-native expect-native"
|
|
DEPENDS += "binutils-native"
|
|
|
|
deltask do_compile
|
|
deltask do_install
|
|
|
|
inherit nopackages
|
|
|
|
do_configure[dirs] += "${B}/ld ${B}/bfd"
|
|
do_configure() {
|
|
# create config.h, oe enables initfini-array by default
|
|
echo "#define HAVE_INITFINI_ARRAY" > ${B}/ld/config.h
|
|
}
|
|
|
|
# target depends
|
|
DEPENDS += "virtual/cross-binutils"
|
|
DEPENDS += "virtual/cross-cc"
|
|
DEPENDS += "virtual/${MLPREFIX}compilerlibs"
|
|
DEPENDS += "virtual/${MLPREFIX}libc"
|
|
|
|
python check_prepare() {
|
|
def suffix_sys(sys):
|
|
if sys.endswith("-linux"):
|
|
return sys + "-gnu"
|
|
return sys
|
|
|
|
def generate_site_exp(d, suite):
|
|
content = []
|
|
content.append('set srcdir "{0}/{1}"'.format(d.getVar("S"), suite))
|
|
content.append('set objdir "{0}/{1}"'.format(d.getVar("B"), suite))
|
|
content.append('set build_alias "{0}"'.format(d.getVar("BUILD_SYS")))
|
|
content.append('set build_triplet {0}'.format(d.getVar("BUILD_SYS")))
|
|
# use BUILD here since HOST=TARGET
|
|
content.append('set host_alias "{0}"'.format(d.getVar("BUILD_SYS")))
|
|
content.append('set host_triplet {0}'.format(d.getVar("BUILD_SYS")))
|
|
content.append('set target_alias "{0}"'.format(d.getVar("TARGET_SYS")))
|
|
content.append('set target_triplet {0}'.format(suffix_sys(d.getVar("TARGET_SYS"))))
|
|
content.append("set development true")
|
|
content.append("set experimental false")
|
|
|
|
content.append(d.expand('set CXXFILT "${TARGET_PREFIX}c++filt"'))
|
|
content.append(d.expand('set CC "${TARGET_PREFIX}gcc --sysroot=${STAGING_DIR_TARGET} ${TUNE_CCARGS}"'))
|
|
content.append(d.expand('set CXX "${TARGET_PREFIX}g++ --sysroot=${STAGING_DIR_TARGET} ${TUNE_CCARGS}"'))
|
|
content.append(d.expand('set CFLAGS_FOR_TARGET "--sysroot=${STAGING_DIR_TARGET} ${TUNE_CCARGS}"'))
|
|
content.append(d.expand('set LD "${TARGET_PREFIX}ld ${TUNE_LDARGS}"'))
|
|
content.append(d.expand('set LDFLAGS_FOR_TARGET "${TUNE_LDARGS}"'))
|
|
|
|
if suite == "ld" and d.getVar("TUNE_ARCH") == "mips64":
|
|
# oe patches binutils to have the default mips64 abi as 64bit, but
|
|
# skips gas causing issues with the ld test suite (which uses gas)
|
|
content.append('set ASFLAGS "-64"')
|
|
|
|
return "\n".join(content)
|
|
|
|
for i in ["binutils", "gas", "ld"]:
|
|
builddir = os.path.join(d.getVar("B"), i)
|
|
if not os.path.isdir(builddir):
|
|
os.makedirs(builddir)
|
|
with open(os.path.join(builddir, "site.exp"), "w") as f:
|
|
f.write(generate_site_exp(d, i))
|
|
}
|
|
|
|
CHECK_TARGETS ??= "binutils gas ld"
|
|
|
|
do_check[dirs] = "${B} ${B}/binutils ${B}/gas ${B}/ld"
|
|
do_check[prefuncs] += "check_prepare"
|
|
do_check[nostamp] = "1"
|
|
do_check() {
|
|
export LC_ALL=C
|
|
for i in ${CHECK_TARGETS}; do
|
|
(cd ${B}/$i; runtest \
|
|
--tool $i \
|
|
--srcdir ${S}/$i/testsuite \
|
|
--ignore 'plugin.exp' \
|
|
|| true)
|
|
done
|
|
}
|
|
addtask check after do_configure
|