mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
de963051ee
The 'opkg-key' utility requires gpg to manage the list of trusted keys. The ability to verify package signatures is not much use without the ability to add keys to the trusted list... (From OE-Core rev: ebd7dce320dfdbac449b60e23cfe41125b658319) Signed-off-by: Paul Barker <paul@paulbarker.me.uk> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
77 lines
2.5 KiB
PHP
77 lines
2.5 KiB
PHP
SUMMARY = "Open Package Manager"
|
|
SUMMARY_libopkg = "Open Package Manager library"
|
|
SECTION = "base"
|
|
HOMEPAGE = "http://code.google.com/p/opkg/"
|
|
BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://src/opkg-cl.c;beginline=1;endline=20;md5=321f658c3f6b6c832e25c8850b5dffba"
|
|
|
|
PE = "1"
|
|
|
|
# Werror gives all kinds bounds issuses with gcc 4.3.3
|
|
do_configure_prepend() {
|
|
sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
|
|
}
|
|
|
|
inherit autotools pkgconfig systemd
|
|
|
|
python () {
|
|
if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
|
|
pn = d.getVar('PN', True)
|
|
d.setVar('SYSTEMD_SERVICE_%s' % (pn), 'opkg-configure.service')
|
|
}
|
|
|
|
target_localstatedir := "${localstatedir}"
|
|
OPKGLIBDIR = "${target_localstatedir}/lib"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
|
|
PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,gpgme libgpg-error,gnupg"
|
|
PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
|
|
PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
|
|
PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
|
|
PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
|
|
PACKAGECONFIG[pathfinder] = "--enable-pathfinder,--disable-pathfinder,pathfinder"
|
|
|
|
EXTRA_OECONF = "\
|
|
--with-opkglibdir=${OPKGLIBDIR} \
|
|
"
|
|
|
|
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base run-postinsts"
|
|
RDEPENDS_${PN}_class-native = ""
|
|
RDEPENDS_${PN}_class-nativesdk = ""
|
|
RREPLACES_${PN} = "opkg-nogpg"
|
|
|
|
PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
|
|
|
|
FILES_libopkg-dev = "${libdir}/*.la ${libdir}/*.so ${includedir}/libopkg"
|
|
FILES_libopkg-staticdev = "${libdir}/*.a"
|
|
FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
|
|
FILES_${PN} += "${systemd_unitdir}/system/"
|
|
|
|
do_install_append() {
|
|
# We need to create the lock directory
|
|
install -d ${D}${OPKGLIBDIR}/opkg
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)};then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${WORKDIR}/opkg-configure.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
|
|
-e 's,@SYSCONFDIR@,${sysconfdir},g' \
|
|
-e 's,@BINDIR@,${bindir},g' \
|
|
-e 's,@SYSTEMD_UNITDIR@,${systemd_unitdir},g' \
|
|
${D}${systemd_unitdir}/system/opkg-configure.service
|
|
fi
|
|
|
|
# The installed binary is 'opkg-cl' but people and scripts often expect
|
|
# it to just be 'opkg'
|
|
ln -sf opkg-cl ${D}${bindir}/opkg
|
|
}
|
|
|
|
do_install_append() {
|
|
rm ${D}${bindir}/update-alternatives
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|