mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
c422202315
If a machine has vfat in its MACHINE_FEATURES, we can ensure that the kernel has support by enabling the associated KERNEL_FEATURE. This partially addresses Yocto bug 14470. (From OE-Core rev: bc61fdbb5f6e409ee03e8939bcefa133debdc028) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
2.1 KiB
PHP
60 lines
2.1 KiB
PHP
SUMMARY = "Linux kernel"
|
|
SECTION = "kernel"
|
|
LICENSE = "GPLv2"
|
|
HOMEPAGE = "https://www.yoctoproject.org/"
|
|
|
|
LIC_FILES_CHKSUM ?= "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+\.\d+(\.\d+)*)"
|
|
|
|
RECIPE_NO_UPDATE_REASON = "Recipe is updated through a separate process"
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids network access required
|
|
# by the use of AUTOREV SRCREVs, which are the default for this recipe.
|
|
python () {
|
|
if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != d.getVar("PN"):
|
|
d.delVar("BB_DONT_CACHE")
|
|
raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to %s to enable it" % (d.getVar("PN")))
|
|
}
|
|
|
|
DEPENDS += "xz-native bc-native"
|
|
DEPENDS_append_aarch64 = " libgcc"
|
|
KERNEL_CC_append_aarch64 = " ${TOOLCHAIN_OPTIONS}"
|
|
KERNEL_LD_append_aarch64 = " ${TOOLCHAIN_OPTIONS}"
|
|
|
|
DEPENDS_append_nios2 = " libgcc"
|
|
KERNEL_CC_append_nios2 = " ${TOOLCHAIN_OPTIONS}"
|
|
KERNEL_LD_append_nios2 = " ${TOOLCHAIN_OPTIONS}"
|
|
|
|
DEPENDS_append_arc = " libgcc"
|
|
KERNEL_CC_append_arc = " ${TOOLCHAIN_OPTIONS}"
|
|
KERNEL_LD_append_arc = " ${TOOLCHAIN_OPTIONS}"
|
|
|
|
KERNEL_FEATURES_append_qemuall=" features/debug/printk.scc"
|
|
|
|
KERNEL_FEATURES_append = " ${@bb.utils.contains('MACHINE_FEATURES', 'numa', 'features/numa/numa.scc', '', d)}"
|
|
KERNEL_FEATURES_append = " ${@bb.utils.contains('MACHINE_FEATURES', 'vfat', 'cfg/fs/vfat.scc', '', d)}"
|
|
|
|
# A KMACHINE is the mapping of a yocto $MACHINE to what is built
|
|
# by the kernel. This is typically the branch that should be built,
|
|
# and it can be specific to the machine or shared
|
|
# KMACHINE = "UNDEFINED"
|
|
|
|
LINUX_VERSION_EXTENSION ??= "-yocto-${LINUX_KERNEL_TYPE}"
|
|
|
|
# Pick up shared functions
|
|
inherit kernel
|
|
inherit kernel-yocto
|
|
|
|
B = "${WORKDIR}/linux-${PACKAGE_ARCH}-${LINUX_KERNEL_TYPE}-build"
|
|
|
|
do_install_append(){
|
|
if [ -n "${KMETA}" ]; then
|
|
rm -rf ${STAGING_KERNEL_DIR}/${KMETA}
|
|
fi
|
|
}
|
|
|
|
# enable kernel-sample for oeqa/runtime/cases's ksample.py test
|
|
KERNEL_FEATURES_append_qemuall=" features/kernel-sample/kernel-sample.scc"
|