mirror of
https://git.yoctoproject.org/poky
synced 2026-02-13 12:13:02 +01:00
1eeda313f6
NEWS * Noteworthy changes in release 3.9 (2023-01-15) [stable] ** Bug fixes diff -c and -u no longer output incorrect timezones in headers on platforms like Solaris where struct tm lacks tm_gmtoff. [bug#51228 introduced in 3.4] Drop patch as issue fixed upstream. (From OE-Core rev: 686bb89d7553f48c029b6f6d79c88304f2dc0c55) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit e5ec5de7217de28bccf3243496df6b41ca8a1d0b) Signed-off-by: Steve Sakoman <steve@sakoman.com> (cherry picked from commit 6bf52987a82370a1353399a480271a76237e7619) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.4 KiB
BlitzBasic
44 lines
1.4 KiB
BlitzBasic
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
require diffutils.inc
|
|
|
|
SRC_URI = "${GNU_MIRROR}/diffutils/diffutils-${PV}.tar.xz \
|
|
file://run-ptest \
|
|
file://0001-Skip-strip-trailing-cr-test-case.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "d80d3be90a201868de83d78dad3413ad88160cc53bcc36eb9eaf7c20dbf023f1"
|
|
|
|
EXTRA_OECONF += "ac_cv_path_PR_PROGRAM=${bindir}/pr --without-libsigsegv-prefix"
|
|
|
|
# latest gnulib is no longer able to handle this - I dare not try to fix that maze of abstractions and generators
|
|
CFLAGS:mingw32 = " -DSA_RESTART=0"
|
|
|
|
# Fix "Argument list too long" error when len(TMPDIR) = 410
|
|
acpaths = "-I ./m4"
|
|
|
|
EXTRA_OEMAKE:append:mingw32 = " LIBS='-lbcrypt'"
|
|
inherit ptest
|
|
|
|
RDEPENDS:${PN}-ptest += "make perl"
|
|
|
|
do_install_ptest() {
|
|
t=${D}${PTEST_PATH}
|
|
install -D ${S}/build-aux/test-driver $t/build-aux/test-driver
|
|
cp -r ${S}/tests $t/
|
|
install ${B}/tests/Makefile $t/tests/
|
|
sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
|
-e 's|^Makefile:|_Makefile:|' \
|
|
-e 's|bash|sh|' \
|
|
-e 's|^top_srcdir = \(.*\)|top_srcdir = ..\/|' \
|
|
-e 's|^srcdir = \(.*\)|srcdir = .|' \
|
|
-e 's|"`$(built_programs)`"|diff|' \
|
|
-e 's|gawk|awk|g' \
|
|
-i $t/tests/Makefile
|
|
}
|