mirror of
https://git.yoctoproject.org/poky
synced 2026-07-02 17:13:39 +02:00
77feabea24
Libarchive is being used by OPKG package manager as default API for extracting tar files. This fix allows us to extract ipks packages with preserved ACLs and xattrs. Partially addresses [YOCTO #15091] [RP: Merge into main PACKAGECONFIG and tweak commit message] (From OE-Core rev: b1f80f0a2bf30698192c7a214c5802b76464d095) Signed-off-by: Piotr Łobacz <p.lobacz@welotec.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 913aad1ac013368aef8f6af332588ef24bba46bd) Signed-off-by: Steve Sakoman <steve@sakoman.com>
64 lines
2.3 KiB
BlitzBasic
64 lines
2.3 KiB
BlitzBasic
SUMMARY = "Support for reading various archive formats"
|
|
DESCRIPTION = "C library and command-line tools for reading and writing tar, cpio, zip, ISO, and other archive formats"
|
|
HOMEPAGE = "http://www.libarchive.org/"
|
|
SECTION = "devel"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d499814247adaee08d88080841cb5665"
|
|
|
|
DEPENDS = "e2fsprogs-native"
|
|
|
|
PACKAGECONFIG ?= "zlib bz2 xz lzo zstd ${@bb.utils.filter('DISTRO_FEATURES', 'acl xattr', d)}"
|
|
|
|
DEPENDS_BZIP2 = "bzip2-replacement-native"
|
|
DEPENDS_BZIP2:class-target = "bzip2"
|
|
|
|
PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
|
|
PACKAGECONFIG[xattr] = "--enable-xattr,--disable-xattr,attr,"
|
|
PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib,"
|
|
PACKAGECONFIG[bz2] = "--with-bz2lib,--without-bz2lib,${DEPENDS_BZIP2},"
|
|
PACKAGECONFIG[xz] = "--with-lzma,--without-lzma,xz,"
|
|
PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl,"
|
|
PACKAGECONFIG[libxml2] = "--with-xml2,--without-xml2,libxml2,"
|
|
PACKAGECONFIG[expat] = "--with-expat,--without-expat,expat,"
|
|
PACKAGECONFIG[lzo] = "--with-lzo2,--without-lzo2,lzo,"
|
|
PACKAGECONFIG[nettle] = "--with-nettle,--without-nettle,nettle,"
|
|
PACKAGECONFIG[lz4] = "--with-lz4,--without-lz4,lz4,"
|
|
PACKAGECONFIG[mbedtls] = "--with-mbedtls,--without-mbedtls,mbedtls,"
|
|
PACKAGECONFIG[zstd] = "--with-zstd,--without-zstd,zstd,"
|
|
|
|
EXTRA_OECONF += "--enable-largefile --without-iconv"
|
|
|
|
SRC_URI = "http://libarchive.org/downloads/libarchive-${PV}.tar.gz"
|
|
UPSTREAM_CHECK_URI = "http://libarchive.org/"
|
|
|
|
SRC_URI[sha256sum] = "ba6d02f15ba04aba9c23fd5f236bb234eab9d5209e95d1c4df85c44d5f19b9b3"
|
|
|
|
inherit autotools update-alternatives pkgconfig
|
|
|
|
CPPFLAGS += "-I${WORKDIR}/extra-includes"
|
|
|
|
do_configure[cleandirs] += "${WORKDIR}/extra-includes"
|
|
do_configure:prepend() {
|
|
# We just need the headers for some type constants, so no need to
|
|
# build all of e2fsprogs for the target
|
|
cp -R ${STAGING_INCDIR_NATIVE}/ext2fs ${WORKDIR}/extra-includes/
|
|
}
|
|
|
|
ALTERNATIVE_PRIORITY = "80"
|
|
|
|
PACKAGES =+ "bsdtar"
|
|
FILES:bsdtar = "${bindir}/bsdtar"
|
|
|
|
ALTERNATIVE:bsdtar = "tar"
|
|
ALTERNATIVE_LINK_NAME[tar] = "${base_bindir}/tar"
|
|
ALTERNATIVE_TARGET[tar] = "${bindir}/bsdtar"
|
|
|
|
PACKAGES =+ "bsdcpio"
|
|
FILES:bsdcpio = "${bindir}/bsdcpio"
|
|
|
|
ALTERNATIVE:bsdcpio = "cpio"
|
|
ALTERNATIVE_LINK_NAME[cpio] = "${base_bindir}/cpio"
|
|
ALTERNATIVE_TARGET[cpio] = "${bindir}/bsdcpio"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|