mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 02:33:02 +01:00
3bc80c214a
Martin Jansa spotted patchreview.py reports Malformed Upstream-Status in a patch in this recipe. The patch is not being applied since there is no ptest override. The test in question was also disabled due to an issue with new versions of openssh. Add a workaround for the broken test, enable it, drop the broken patch. (From OE-Core rev: 2c05ee17d58774fc628b8a5b55a14551590fadaa) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit e9f2cc084638ce9cb5339df611e473c30f0e40b1) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.6 KiB
BlitzBasic
50 lines
1.6 KiB
BlitzBasic
SUMMARY = "A client-side C library implementing the SSH2 protocol"
|
|
HOMEPAGE = "http://www.libssh2.org/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=3e089ad0cf27edf1e7f261dfcd06acc7"
|
|
|
|
SRC_URI = "http://www.libssh2.org/download/${BP}.tar.gz \
|
|
file://fix-ssh2-test.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "2d64e90f3ded394b91d3a2e774ca203a4179f69aebee03003e5a6fa621e41d51"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
EXTRA_OECONF += "\
|
|
--with-libz \
|
|
--with-libz-prefix=${STAGING_LIBDIR} \
|
|
"
|
|
|
|
# only one of openssl and gcrypt could be set
|
|
PACKAGECONFIG ??= "openssl"
|
|
PACKAGECONFIG[openssl] = "--with-crypto=openssl --with-libssl-prefix=${STAGING_LIBDIR}, , openssl"
|
|
PACKAGECONFIG[gcrypt] = "--with-crypto=libgcrypt --with-libgcrypt-prefix=${STAGING_EXECPREFIXDIR}, , libgcrypt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# required for ptest on documentation
|
|
RDEPENDS:${PN}-ptest = "man-db openssh util-linux-col"
|
|
RDEPENDS:${PN}-ptest:append:libc-glibc = " locale-base-en-us"
|
|
|
|
do_compile_ptest() {
|
|
sed -i "/\$(MAKE) \$(AM_MAKEFLAGS) check-TESTS/d" tests/Makefile
|
|
oe_runmake check
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -m 0755 ${S}/test-driver ${D}${PTEST_PATH}/
|
|
cp -rf ${B}/tests/.libs/* ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/mansyntax.sh ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/ssh2.sh ${D}${PTEST_PATH}/tests/
|
|
cp -rf ${S}/tests/etc ${D}${PTEST_PATH}/tests/
|
|
mkdir -p ${D}${PTEST_PATH}/docs
|
|
cp -r ${S}/docs/* ${D}${PTEST_PATH}/docs/
|
|
}
|