mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 09:32:11 +02:00
0749e35a37
gcc does not have it but clang does, problem happens when host compiler is gcc and cross compiler is clang, because autoconf detects it with clang and slaps it to host compiler as well (From OE-Core rev: c70d915bcc3054120e7ad06b9bcfef57f2d15371) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1.5 KiB
BlitzBasic
37 lines
1.5 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "http://ftp.sudo.ws/sudo/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-Use-correct-path-to-init.d-and-tmpfiles.d-files.patch \
|
|
file://0001-Include-sys-types.h-for-id_t-definition.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[md5sum] = "93dbd1e47c136179ff1b01494c1c0e75"
|
|
SRC_URI[sha256sum] = "a8a697cbb113859058944850d098464618254804cf97961dee926429f00a1237"
|
|
|
|
DEPENDS += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
EXTRA_OECONF += " \
|
|
ac_cv_type_rsize_t=no \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
"
|
|
|
|
do_install_append () {
|
|
if [ "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)}" = "pam" ]; then
|
|
install -D -m 664 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the ${localstatedir}/run directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}${localstatedir}/run/sudo
|
|
}
|
|
|
|
FILES_${PN} += "${libdir}/tmpfiles.d"
|
|
FILES_${PN}-dev += "${libdir}/${BPN}/lib*${SOLIBSDEV} ${libdir}/${BPN}/*.la"
|