mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 02:03:04 +01:00
760e81678c
* This is converging the recipes for go from meta-virtualization and oe-meta-go * Add recipes for go 1.7 * go.bbclass is added to ease out writing recipes for go packages * go-examples: Add an example, helloworld written in go This should serve as temlate for writing go recipes * Disable for musl, at least for now * Disable for x32/ppc32 which is not supported (From OE-Core rev: 78615e9260fb5d6569de4883521b049717fa4340) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
2.4 KiB
Plaintext
80 lines
2.4 KiB
Plaintext
inherit goarch
|
|
|
|
# Incompatible with musl, at least for now
|
|
COMPATIBLE_HOST_libc-musl_class-target = "null"
|
|
# x32 ABI is not supported on go compiler so far
|
|
COMPATIBLE_HOST_linux-gnux32 = "null"
|
|
# ppc32 is not supported in go compilers
|
|
COMPATIBLE_HOST_powerpc = "null"
|
|
|
|
GOROOT_class-native = "${STAGING_LIBDIR_NATIVE}/go"
|
|
GOROOT = "${STAGING_LIBDIR_NATIVE}/${TARGET_SYS}/go"
|
|
GOBIN_FINAL_class-native = "${GOROOT_FINAL}/bin"
|
|
GOBIN_FINAL = "${GOROOT_FINAL}/bin/${GOOS}_${GOARCH}"
|
|
|
|
export GOOS = "${TARGET_GOOS}"
|
|
export GOARCH = "${TARGET_GOARCH}"
|
|
export GOARM = "${TARGET_GOARM}"
|
|
export CGO_ENABLED = "1"
|
|
export GOROOT
|
|
export GOROOT_FINAL = "${libdir}/${TARGET_SYS}/go"
|
|
export GOBIN_FINAL
|
|
export GOPKG_FINAL = "${GOROOT_FINAL}/pkg/${GOOS}_${GOARCH}"
|
|
export GOSRC_FINAL = "${GOROOT_FINAL}/src"
|
|
export GO_GCFLAGS = "${TARGET_CFLAGS}"
|
|
export GO_LDFLAGS = "${TARGET_LDFLAGS}"
|
|
export CGO_CFLAGS = "${TARGET_CC_ARCH}${TOOLCHAIN_OPTIONS} ${TARGET_CFLAGS}"
|
|
export CGO_CPPFLAGS = "${TARGET_CPPFLAGS}"
|
|
export CGO_CXXFLAGS = "${TARGET_CC_ARCH}${TOOLCHAIN_OPTIONS} ${TARGET_CXXFLAGS}"
|
|
export CGO_LDFLAGS = "${TARGET_CC_ARCH}${TOOLCHAIN_OPTIONS} ${TARGET_LDFLAGS}"
|
|
|
|
DEPENDS += "go-cross-${TARGET_ARCH}"
|
|
DEPENDS_class-native += "go-native"
|
|
|
|
FILES_${PN}-staticdev += "${GOSRC_FINAL}/${GO_IMPORT}"
|
|
FILES_${PN}-staticdev += "${GOPKG_FINAL}/${GO_IMPORT}*"
|
|
|
|
GO_INSTALL ?= "${GO_IMPORT}/..."
|
|
|
|
do_go_compile() {
|
|
GOPATH=${S}:${STAGING_LIBDIR}/${TARGET_SYS}/go go env
|
|
if test -n "${GO_INSTALL}" ; then
|
|
GOPATH=${S}:${STAGING_LIBDIR}/${TARGET_SYS}/go go install -v ${GO_INSTALL}
|
|
fi
|
|
}
|
|
|
|
do_go_install() {
|
|
rm -rf ${WORKDIR}/staging
|
|
install -d ${WORKDIR}/staging${GOROOT_FINAL} ${D}${GOROOT_FINAL}
|
|
tar -C ${S} -cf - . | tar -C ${WORKDIR}/staging${GOROOT_FINAL} -xpvf -
|
|
|
|
find ${WORKDIR}/staging${GOROOT_FINAL} \( \
|
|
-name \*.indirectionsymlink -o \
|
|
-name .git\* -o \
|
|
-name .hg -o \
|
|
-name .svn -o \
|
|
-name .pc\* -o \
|
|
-name patches\* \
|
|
\) -print0 | \
|
|
xargs -r0 rm -rf
|
|
|
|
tar -C ${WORKDIR}/staging${GOROOT_FINAL} -cf - . | \
|
|
tar -C ${D}${GOROOT_FINAL} -xpvf -
|
|
|
|
chown -R root:root "${D}${GOROOT_FINAL}"
|
|
|
|
if test -e "${D}${GOBIN_FINAL}" ; then
|
|
install -d -m 0755 "${D}${bindir}"
|
|
find "${D}${GOBIN_FINAL}" ! -type d -print0 | xargs -r0 mv --target-directory="${D}${bindir}"
|
|
rmdir -p "${D}${GOBIN_FINAL}" || true
|
|
fi
|
|
}
|
|
|
|
do_compile() {
|
|
do_go_compile
|
|
}
|
|
|
|
do_install() {
|
|
do_go_install
|
|
}
|