mirror of
https://git.yoctoproject.org/poky
synced 2026-03-09 00:39:39 +01:00
aaf405efd5
Latest stable branch update which includes 396 commits and the full
list of changes can be found at:
https://github.com/systemd/systemd-stable/compare/v250.5...v250.14
All the patches were refreshed with devtool.
Backported this upstreamed patch to resolve the compile error while
building systemd with qemumips machine.
- 0001-core-fix-build-when-seccomp-is-off.patch
These 2 below patches were modified to resolve the merge conflicts
introduced by systemd v250.14 version:
1. 0001-Move-sysusers.d-sysctl.d-binfmt.d-modules-load.d-to-.patch
- This patch was just adjusted based on the systemd v250.14 version.
2. 0001-pass-correct-parameters-to-getdents64.patch
- For this patch, there was a commit reverted as part of the v250.8 tag:
51089e007f
These below 6 patches were dropped as systemd v250.14 already has
the changes:
- 0001-shared-json-allow-json_variant_dump-to-return-an-err.patch
- CVE-2022-3821.patch
- CVE-2022-4415-1.patch
- CVE-2022-4415-2.patch
- CVE-2022-45873.patch
- CVE-2023-7008.patch
(From OE-Core rev: 371d030a665e3c963a586ab02d10f1f36b225435)
Signed-off-by: Narpat Mali <narpat.falna@gmail.com>
Signed-off-by: Randy Macleod <randy.macleod@windriver.com>
Signed-off-by: Steve Sakoman <steve@sakoman.com>
74 lines
2.1 KiB
BlitzBasic
74 lines
2.1 KiB
BlitzBasic
require systemd.inc
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemd:"
|
|
|
|
require conf/image-uefi.conf
|
|
|
|
DEPENDS = "intltool-native libcap util-linux gnu-efi gperf-native python3-jinja2-native"
|
|
|
|
inherit meson pkgconfig gettext
|
|
inherit deploy
|
|
|
|
LDFLAGS:prepend = "${@ " ".join(d.getVar('LD').split()[1:])} "
|
|
|
|
do_write_config[vardeps] += "CC OBJCOPY"
|
|
do_write_config:append() {
|
|
cat >${WORKDIR}/meson-${PN}.cross <<EOF
|
|
[binaries]
|
|
efi_cc = ${@meson_array('CC', d)}
|
|
objcopy = ${@meson_array('OBJCOPY', d)}
|
|
EOF
|
|
}
|
|
|
|
EFI_LD = "bfd"
|
|
|
|
EXTRA_OEMESON += "-Defi=true \
|
|
-Dgnu-efi=true \
|
|
-Defi-includedir=${STAGING_INCDIR}/efi \
|
|
-Defi-libdir=${STAGING_LIBDIR} \
|
|
-Defi-ld=${EFI_LD} \
|
|
-Dman=false \
|
|
--cross-file ${WORKDIR}/meson-${PN}.cross \
|
|
"
|
|
|
|
# install to the image as boot*.efi if its the EFI_PROVIDER,
|
|
# otherwise install as the full name.
|
|
# This allows multiple bootloaders to coexist in a single image.
|
|
python __anonymous () {
|
|
import re
|
|
target = d.getVar('TARGET_ARCH')
|
|
prefix = "" if d.getVar('EFI_PROVIDER') == "systemd-boot" else "systemd-"
|
|
systemdimage = prefix + d.getVar("EFI_BOOT_IMAGE")
|
|
d.setVar("SYSTEMD_BOOT_IMAGE", systemdimage)
|
|
prefix = "systemd-" if prefix == "" else ""
|
|
d.setVar("SYSTEMD_BOOT_IMAGE_PREFIX", prefix)
|
|
}
|
|
|
|
FILES:${PN} = "${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}"
|
|
|
|
RDEPENDS:${PN} += "virtual-systemd-bootconf"
|
|
|
|
# Imported from the old gummiboot recipe
|
|
TUNE_CCARGS:remove = "-mfpmath=sse"
|
|
|
|
COMPATIBLE_HOST = "(aarch64.*|arm.*|x86_64.*|i.86.*)-linux"
|
|
COMPATIBLE_HOST:x86-x32 = "null"
|
|
|
|
do_compile() {
|
|
ninja \
|
|
src/boot/efi/${SYSTEMD_BOOT_IMAGE_PREFIX}${SYSTEMD_BOOT_IMAGE} \
|
|
src/boot/efi/linux${EFI_ARCH}.efi.stub
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${EFI_FILES_PATH}
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${D}${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}
|
|
}
|
|
|
|
do_deploy () {
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${DEPLOYDIR}
|
|
install ${B}/src/boot/efi/linux*.efi.stub ${DEPLOYDIR}
|
|
}
|
|
|
|
addtask deploy before do_build after do_compile
|
|
|