mirror of
https://git.yoctoproject.org/poky
synced 2026-03-10 01:09:40 +01:00
6d48a8cd43
Add a PACKAGECONFIG option for slirp, defaulting to internal. This avoids the presence of libslirp on the host causing qemu to link against that instead breaking reproducibility and usability of the binary on hosts where the library isn't present. We need to add it to PACKAGECONFIG by default since users do expect slirp to be enabled in the wider community. (From OE-Core rev: 9637a46258a596ccb0a7ddc350b33a5fc6c7872e) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 5a9a64132bf5ecac9d611d29751226a466c4a2c1) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
33 lines
1.1 KiB
BlitzBasic
33 lines
1.1 KiB
BlitzBasic
BPN = "qemu"
|
|
|
|
inherit python3-dir
|
|
|
|
require qemu-native.inc
|
|
|
|
# As some of the files installed by qemu-native and qemu-system-native
|
|
# are the same, we depend on qemu-native to get the full installation set
|
|
# and avoid file clashes
|
|
DEPENDS = "glib-2.0-native zlib-native pixman-native qemu-native bison-native meson-native ninja-native"
|
|
|
|
EXTRA_OECONF:append = " --target-list=${@get_qemu_system_target_list(d)}"
|
|
|
|
PACKAGECONFIG ??= "fdt alsa kvm pie slirp \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
|
|
"
|
|
|
|
# Handle distros such as CentOS 5 32-bit that do not have kvm support
|
|
PACKAGECONFIG:remove = "${@'kvm' if not os.path.exists('/usr/include/linux/kvm.h') else ''}"
|
|
|
|
do_install:append() {
|
|
install -Dm 0755 ${WORKDIR}/powerpc_rom.bin ${D}${datadir}/qemu
|
|
|
|
# The following is also installed by qemu-native
|
|
rm -f ${D}${datadir}/qemu/trace-events-all
|
|
rm -rf ${D}${datadir}/qemu/keymaps
|
|
rm -rf ${D}${datadir}/icons/
|
|
rm -rf ${D}${includedir}/qemu-plugin.h
|
|
|
|
# Install qmp.py to be used with testimage
|
|
install -D ${S}/python/qemu/qmp/__init__.py ${D}${libdir}/qemu-python/qmp.py
|
|
}
|