mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 21:32:13 +02:00
da9b588be4
Same was done in newer Yocto releases. See commit See commit 0f2cd2bbaddba3b8c80d71db274bbcd941d0e60e (From OE-Core rev: 50d8a653104abb9b5cd8a708a7bd97446e894bcf) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
55 lines
1.7 KiB
BlitzBasic
55 lines
1.7 KiB
BlitzBasic
SUMMARY = "GNU cpio is a program to manage archives of files"
|
|
DESCRIPTION = "GNU cpio is a tool for creating and extracting archives, or copying files from one place to \
|
|
another. It handles a number of cpio formats as well as reading and writing tar files."
|
|
HOMEPAGE = "http://www.gnu.org/software/cpio/"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=f27defe1e96c2e1ecd4e0c9be8967949"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/cpio/cpio-${PV}.tar.gz \
|
|
file://0001-configure-Include-needed-header-for-major-minor-macr.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "145a340fd9d55f0b84779a44a12d5f79d77c99663967f8cfa168d7905ca52454"
|
|
|
|
inherit autotools gettext texinfo
|
|
|
|
# Issue applies to use of cpio in SUSE/OBS, doesn't apply to us
|
|
CVE_CHECK_IGNORE += "CVE-2010-4226"
|
|
# disputed: intended behaviour, see https://lists.gnu.org/archive/html/bug-cpio/2024-03/msg00000.html
|
|
CVE_CHECK_IGNORE += "CVE-2023-7216"
|
|
|
|
EXTRA_OECONF += "DEFAULT_RMT_DIR=${sbindir}"
|
|
|
|
do_install () {
|
|
autotools_do_install
|
|
if [ "${base_bindir}" != "${bindir}" ]; then
|
|
install -d ${D}${base_bindir}/
|
|
mv "${D}${bindir}/cpio" "${D}${base_bindir}/cpio"
|
|
if [ "${sbindir}" != "${bindir}" ]; then
|
|
rmdir ${D}${bindir}/
|
|
fi
|
|
fi
|
|
|
|
# Avoid conflicts with the version from tar
|
|
mv "${D}${mandir}/man8/rmt.8" "${D}${mandir}/man8/rmt-cpio.8"
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-rmt"
|
|
|
|
FILES:${PN}-rmt = "${sbindir}/rmt*"
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE:${PN} = "cpio"
|
|
ALTERNATIVE:${PN}-rmt = "rmt"
|
|
|
|
ALTERNATIVE_LINK_NAME[cpio] = "${base_bindir}/cpio"
|
|
|
|
ALTERNATIVE_PRIORITY[rmt] = "50"
|
|
ALTERNATIVE_LINK_NAME[rmt] = "${sbindir}/rmt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|