mirror of
https://git.yoctoproject.org/poky
synced 2026-03-09 00:39:39 +01:00
50475a377a
A minor information leak when running Screen with setuid-root privileges allosw unprivileged users to deduce information about a path that would otherwise not be available. Affected are older Screen versions, as well as version 5.0.0. Reference: https://security-tracker.debian.org/tracker/CVE-2025-46804 Upstream-patch: https://cgit.git.savannah.gnu.org/cgit/screen.git/commit/?id=e0eef5aac453fa98a2664416a56c50ad1d00cb30 (From OE-Core rev: fa14b05383a322f5fe751c81e8c6f1a8a1df8c9e) Signed-off-by: Divya Chellam <divya.chellam@windriver.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
54 lines
2.1 KiB
BlitzBasic
54 lines
2.1 KiB
BlitzBasic
SUMMARY = "Multiplexing terminal manager"
|
|
DESCRIPTION = "Screen is a full-screen window manager \
|
|
that multiplexes a physical terminal between several \
|
|
processes, typically interactive shells."
|
|
HOMEPAGE = "http://www.gnu.org/software/screen/"
|
|
BUGTRACKER = "https://savannah.gnu.org/bugs/?func=additem&group=screen"
|
|
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://screen.h;endline=26;md5=b8dc717c9a3dba842ae6c44ca0f73f52 \
|
|
"
|
|
|
|
DEPENDS = "ncurses virtual/crypt \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS:${PN} = "base-files"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/screen/screen-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'file://screen.pam', '', d)} \
|
|
file://0002-comm.h-now-depends-on-term.h.patch \
|
|
file://0001-fix-for-multijob-build.patch \
|
|
file://0001-Remove-more-compatibility-stuff.patch \
|
|
file://CVE-2023-24626.patch \
|
|
file://CVE-2025-46805.patch \
|
|
file://CVE-2025-46802.patch \
|
|
file://CVE-2025-46804.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f9335281bb4d1538ed078df78a20c2f39d3af9a4e91c57d084271e0289c730f4"
|
|
|
|
inherit autotools texinfo
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[utempter] = "ac_cv_header_utempter_h=yes,ac_cv_header_utempter_h=no,libutempter,"
|
|
|
|
EXTRA_OECONF = "--with-pty-mode=0620 --with-pty-group=5 --with-sys-screenrc=${sysconfdir}/screenrc \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam', '--disable-pam', d)}"
|
|
|
|
do_install:append () {
|
|
install -D -m 644 ${S}/etc/etcscreenrc ${D}/${sysconfdir}/screenrc
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${WORKDIR}/screen.pam ${D}/${sysconfdir}/pam.d/screen
|
|
fi
|
|
}
|
|
|
|
pkg_postinst:${PN} () {
|
|
grep -q "^${bindir}/screen$" $D${sysconfdir}/shells || echo ${bindir}/screen >> $D${sysconfdir}/shells
|
|
}
|
|
|
|
pkg_postrm:${PN} () {
|
|
printf "$(grep -v "^${bindir}/screen$" $D${sysconfdir}/shells)\n" > $D${sysconfdir}/shells
|
|
}
|