mirror of
https://git.yoctoproject.org/poky
synced 2026-03-08 08:19:40 +01:00
249617857b
Pick commits from [1] linked from [2] via [3]. [1] https://github.com/facebook/zstd/pull/3220 [2] https://nvd.nist.gov/vuln/detail/CVE-2022-4899 [3] https://github.com/facebook/zstd/issues/3200 (From OE-Core rev: eb9c9818088105f9bf20b7fdc04a380ce488a5e6) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
47 lines
1.5 KiB
BlitzBasic
47 lines
1.5 KiB
BlitzBasic
SUMMARY = "Zstandard - Fast real-time compression algorithm"
|
|
DESCRIPTION = "Zstandard is a fast lossless compression algorithm, targeting \
|
|
real-time compression scenarios at zlib-level and better compression ratios. \
|
|
It's backed by a very fast entropy stage, provided by Huff0 and FSE library."
|
|
HOMEPAGE = "http://www.zstd.net/"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "BSD-3-Clause | GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=c7f0b161edbe52f5f345a3d1311d0b32 \
|
|
file://COPYING;md5=39bba7d2cf0ba1036f2a6e2be52fe3f0"
|
|
|
|
SRC_URI = "git://github.com/facebook/zstd.git;branch=release;protocol=https \
|
|
file://CVE-2022-4899-1.patch \
|
|
file://CVE-2022-4899-2.patch \
|
|
"
|
|
|
|
SRCREV = "e47e674cd09583ff0503f0f6defd6d23d8b718d3"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
|
|
|
|
CVE_PRODUCT = "zstandard"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[lz4] = "HAVE_LZ4=1,HAVE_LZ4=0,lz4"
|
|
PACKAGECONFIG[lzma] = "HAVE_LZMA=1,HAVE_LZMA=0,xz"
|
|
PACKAGECONFIG[zlib] = "HAVE_ZLIB=1,HAVE_ZLIB=0,zlib"
|
|
|
|
# See programs/README.md for how to use this
|
|
ZSTD_LEGACY_SUPPORT ??= "4"
|
|
|
|
do_compile () {
|
|
oe_runmake ${PACKAGECONFIG_CONFARGS} ZSTD_LEGACY_SUPPORT=${ZSTD_LEGACY_SUPPORT}
|
|
oe_runmake ${PACKAGECONFIG_CONFARGS} ZSTD_LEGACY_SUPPORT=${ZSTD_LEGACY_SUPPORT} -C contrib/pzstd
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake install 'DESTDIR=${D}'
|
|
oe_runmake install 'DESTDIR=${D}' PREFIX=${prefix} -C contrib/pzstd
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN = "libzstd"
|
|
|
|
FILES:libzstd = "${libdir}/libzstd${SOLIBS}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|