mirror of
https://git.yoctoproject.org/poky
synced 2026-03-09 16:59:40 +01:00
c6bb0ec77c
This was fixed in 2.0.14, but NVD DB lists > 2.0.20 causing
false positives in CVE metrics.
NVD entries [1] and [2] list commit [3] which redirects to commit [4].
Also Debian 10 uses this commit, while Debian 11 with 2.0.14 does not
patch it and claims it's fixed.
Trying to apply the patch shows it's already applied.
Following shows git history of this commit wrt tags.
SDL$ git describe a7ff6e96155f550a5597621ebeddd03c98aa9294 --tags
release-2.0.12-305-ga7ff6e961
SDL$ git describe release-2.0.14 --tags --match=release-2.0.12
release-2.0.12-873-g4cd981609
SDL$ git describe release-2.0.20 --tags --match=release-2.0.12
release-2.0.12-3126-gb424665e0
[1] https://nvd.nist.gov/vuln/detail/CVE-2020-14409
[2] https://nvd.nist.gov/vuln/detail/CVE-2020-14410
[3] https://hg.libsdl.org/SDL/rev/3f9b4e92c1d9
[4] a7ff6e9615
(From OE-Core rev: 3079d562b4df69ab0ac20ec8d13a4240ce0a3514)
Signed-off-by: Peter Marko <peter.marko@siemens.com>
Signed-off-by: Steve Sakoman <steve@sakoman.com>
88 lines
3.9 KiB
BlitzBasic
88 lines
3.9 KiB
BlitzBasic
SUMMARY = "Simple DirectMedia Layer"
|
|
DESCRIPTION = "Simple DirectMedia Layer is a cross-platform multimedia \
|
|
library designed to provide low level access to audio, keyboard, mouse, \
|
|
joystick, 3D hardware via OpenGL, and 2D video framebuffer."
|
|
HOMEPAGE = "http://www.libsdl.org"
|
|
BUGTRACKER = "http://bugzilla.libsdl.org/"
|
|
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Zlib & BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "\
|
|
file://LICENSE.txt;md5=68a088513da90254b2fbe664f42af315 \
|
|
file://src/hidapi/LICENSE.txt;md5=7c3949a631240cb6c31c50f3eb696077 \
|
|
file://src/hidapi/LICENSE-bsd.txt;md5=b5fa085ce0926bb50d0621620a82361f \
|
|
file://src/video/yuv2rgb/LICENSE;md5=79f8f3418d91531e05f0fc94ca67e071 \
|
|
"
|
|
|
|
# arm-neon adds MIT license
|
|
LICENSE:append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', '& MIT', '', d)}"
|
|
LIC_FILES_CHKSUM:append = " ${@bb.utils.contains('PACKAGECONFIG', 'arm-neon', 'file://src/video/arm/pixman-arm-neon-asm.h;md5=9a9cc1e51abbf1da58f4d9528ec9d49b;beginline=1;endline=24', '', d)}"
|
|
|
|
PROVIDES = "virtual/libsdl2"
|
|
|
|
SRC_URI = "http://www.libsdl.org/release/SDL2-${PV}.tar.gz \
|
|
file://optional-libunwind-generic.patch \
|
|
file://0001-sdlchecks.cmake-pass-cflags-to-the-appropriate-cmake.patch \
|
|
file://0001-Fix-potential-memory-leak-in-GLES_CreateTextur.patch \
|
|
"
|
|
SRC_URI:append:class-native = " file://0001-Disable-libunwind-in-native-OE-builds-by-not-looking.patch"
|
|
|
|
S = "${WORKDIR}/SDL2-${PV}"
|
|
|
|
SRC_URI[sha256sum] = "c56aba1d7b5b0e7e999e4a7698c70b63a3394ff9704b5f6e1c57e0c16f04dd06"
|
|
|
|
inherit cmake lib_package binconfig-disabled pkgconfig
|
|
|
|
BINCONFIG = "${bindir}/sdl2-config"
|
|
|
|
CVE_PRODUCT = "simple_directmedia_layer sdl"
|
|
|
|
EXTRA_OECMAKE = "-DSDL_OSS=OFF -DSDL_ESD=OFF -DSDL_ARTS=OFF \
|
|
-DSDL_DISKAUDIO=OFF -DSDL_NAS=OFF -DSDL_ESD_SHARED=OFF \
|
|
-DSDL_DUMMYVIDEO=OFF \
|
|
-DSDL_RPI=OFF \
|
|
-DSDL_PTHREADS=ON \
|
|
-DSDL_RPATH=OFF \
|
|
-DSDL_SNDIO=OFF \
|
|
-DSDL_X11_XVM=OFF \
|
|
-DSDL_X11_XCURSOR=OFF \
|
|
-DSDL_X11_XINERAMA=OFF \
|
|
-DSDL_X11_XDBE=OFF \
|
|
-DSDL_X11_XFIXES=OFF \
|
|
-DSDL_X11_XINPUT=OFF \
|
|
-DSDL_X11_XRANDR=OFF \
|
|
-DSDL_X11_XSCRNSAVER=OFF \
|
|
-DSDL_X11_XSHAPE=OFF \
|
|
"
|
|
|
|
# opengl packageconfig factored out to make it easy for distros
|
|
# and BSP layers to pick either (desktop) opengl, gles2, or no GL
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.filter('DISTRO_FEATURES', 'opengl', d)}"
|
|
|
|
PACKAGECONFIG:class-native = "x11 ${PACKAGECONFIG_GL}"
|
|
PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} ${PACKAGECONFIG_GL}"
|
|
PACKAGECONFIG ??= " \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'alsa directfb pulseaudio x11', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland gles2', '', d)} \
|
|
${@bb.utils.contains("TUNE_FEATURES", "neon","arm-neon","",d)} \
|
|
"
|
|
PACKAGECONFIG[alsa] = "-DSDL_ALSA=ON,-DSDL_ALSA=OFF,alsa-lib,"
|
|
PACKAGECONFIG[arm-neon] = "-DSDL_ARMNEON=ON,-DSDL_ARMNEON=OFF"
|
|
PACKAGECONFIG[directfb] = "-DSDL_DIRECTFB=ON,-DSDL_DIRECTFB=OFF,directfb,directfb"
|
|
PACKAGECONFIG[gles2] = "-DSDL_OPENGLES=ON,-DSDL_OPENGLES=OFF,virtual/libgles2"
|
|
PACKAGECONFIG[jack] = "-DSDL_JACK=ON,-DSDL_JACK=OFF,jack"
|
|
PACKAGECONFIG[kmsdrm] = "-DSDL_KMSDRM=ON,-DSDL_KMSDRM=OFF,libdrm virtual/libgbm"
|
|
PACKAGECONFIG[opengl] = "-DSDL_OPENGL=ON,-DSDL_OPENGL=OFF,virtual/egl"
|
|
PACKAGECONFIG[pulseaudio] = "-DSDL_PULSEAUDIO=ON,-DSDL_PULSEAUDIO=OFF,pulseaudio"
|
|
PACKAGECONFIG[wayland] = "-DSDL_WAYLAND=ON,-DSDL_WAYLAND=OFF,wayland-native wayland wayland-protocols libxkbcommon"
|
|
PACKAGECONFIG[x11] = "-DSDL_X11=ON,-DSDL_X11=OFF,virtual/libx11 libxext libxrandr libxrender"
|
|
|
|
CFLAGS:append:class-native = " -DNO_SHARED_MEMORY"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# These are fixed since 2.0.14, NVD DB incorrectly lists > 20.0.20
|
|
CVE_CHECK_IGNORE += "CVE-2020-14409 CVE-2020-14410"
|