mirror of
https://git.yoctoproject.org/poky
synced 2026-03-08 08:19:40 +01:00
fcbb7d1cc7
As we just match on product by default, ignore three CVEs which are for the "Puzzles" WordPress theme by ThemeREX (CPE themerex:puzzles). (From OE-Core rev: 87326573c82ac1e8dc335319442236ef2341501e) (From OE-Core rev: 48791ba2329ee930285e5ed8eff0f2535c70bec7) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Adapted to different kirkstone CVE_STATUS format. Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
52 lines
1.5 KiB
BlitzBasic
52 lines
1.5 KiB
BlitzBasic
SUMMARY = "Simon Tatham's Portable Puzzle Collection"
|
|
DESCRIPTION = "Collection of small computer programs which implement one-player puzzle games."
|
|
HOMEPAGE = "http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENCE;md5=6e7d24cf1c949887ee9447a1e2a4a24c"
|
|
|
|
# gtk support includes a bunch of x11 headers
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
SRC_URI = "git://git.tartarus.org/simon/puzzles.git;branch=main"
|
|
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
SRCREV = "c43a34fbfe430d235bafc379595761880a19ed9f"
|
|
PE = "2"
|
|
PV = "0.0+git${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake features_check pkgconfig
|
|
|
|
DEPENDS += "gtk+3"
|
|
|
|
do_install:append () {
|
|
# net conflicts with Samba, so rename it
|
|
mv ${D}${bindir}/net ${D}${bindir}/puzzles-net
|
|
rm ${D}/${datadir}/applications/net.desktop
|
|
|
|
# Create desktop shortcuts
|
|
install -d ${D}/${datadir}/applications/
|
|
cd ${D}/${prefix}/bin
|
|
for prog in *; do
|
|
if [ -x $prog ]; then
|
|
# Convert prog to Title Case
|
|
title=$(echo $prog | sed 's/puzzles-//' | sed 's/\(^\| \)./\U&/g')
|
|
echo "making ${D}/${datadir}/applications/$prog.desktop"
|
|
cat <<STOP > ${D}/${datadir}/applications/$prog.desktop
|
|
[Desktop Entry]
|
|
Name=$title
|
|
Exec=${bindir}/$prog
|
|
Icon=applications-games
|
|
Terminal=false
|
|
Type=Application
|
|
Categories=Game;
|
|
StartupNotify=true
|
|
STOP
|
|
fi
|
|
done
|
|
}
|
|
|
|
# cpe-incorrect: issue in ThemeREX's Wordpress theme Puzzles
|
|
CVE_CHECK_IGNORE += "CVE-2024-13769 CVE-2024-13770 CVE-2025-0837"
|