mirror of
https://git.yoctoproject.org/poky
synced 2026-03-11 01:39:40 +01:00
f01294ea24
Changelog: =========== * Fix logging of confidential data. [rA0fc31770fa] * Fix memory wiping. [T5977] * Fix macOS build problem. [T5440,T5610] * Upgrade autoconf stuff. (From OE-Core rev: a905094c4e7ff3475de657adcf7a0afcc132191a) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 90126be6dc32170c08eb90223b6a6cc06c2133ce) Signed-off-by: Steve Sakoman <steve@sakoman.com>
39 lines
1.4 KiB
BlitzBasic
39 lines
1.4 KiB
BlitzBasic
SUMMARY = "IPC library used by GnuPG and GPGME"
|
|
DESCRIPTION = "A small library implementing the so-called Assuan protocol. \
|
|
This protocol is used for IPC between most newer GnuPG components. \
|
|
Both, server and client side functions are provided. "
|
|
HOMEPAGE = "http://www.gnupg.org/related_software/libassuan/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
|
|
LICENSE = "GPL-3.0-or-later & LGPL-2.1-or-later"
|
|
LICENSE:${PN} = "LGPL-2.1-or-later"
|
|
LICENSE:${PN}-doc = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=f27defe1e96c2e1ecd4e0c9be8967949 \
|
|
file://COPYING.LIB;md5=2d5025d4aa3495befef8f17206a5b0a1 \
|
|
file://src/assuan.c;endline=20;md5=ab92143a5a2adabd06d7994d1467ea5c\
|
|
file://src/assuan-defs.h;endline=20;md5=15d950c83e82978e35b35e790d7e4d39"
|
|
|
|
DEPENDS = "libgpg-error"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
|
|
SRC_URI = "${GNUPG_MIRROR}/libassuan/libassuan-${PV}.tar.bz2 \
|
|
file://libassuan-add-pkgconfig-support.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "e9fd27218d5394904e4e39788f9b1742711c3e6b41689a31aa3380bd5aa4f426"
|
|
|
|
BINCONFIG = "${bindir}/libassuan-config"
|
|
|
|
inherit autotools texinfo binconfig-disabled pkgconfig multilib_header
|
|
|
|
do_configure:prepend () {
|
|
# Else these could be used in preference to those in aclocal-copy
|
|
rm -f ${S}/m4/*.m4
|
|
}
|
|
|
|
do_install:append () {
|
|
oe_multilib_header assuan.h
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|