mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 15:32:12 +02:00
543567bb8a
Github has announced there will be no more git:// fetching from their servers: https://github.blog/2021-09-01-improving-git-protocol-security-github/#no-more-unauthenticated-git and they're about to start having brownout periods to encourage people to update. This runs the conversion script over OE-Core to update our urls to use https instead of git. (From OE-Core rev: 8b83eddda83327d25247bb9b61a049b0a8698a45) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit b37b61e9a1e448a34957db9ae39285d21352552e) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.6 KiB
BlitzBasic
42 lines
1.6 KiB
BlitzBasic
SUMMARY = "3D graphics and compute API common loader"
|
|
DESCRIPTION = "Vulkan is a new generation graphics and compute API \
|
|
that provides efficient access to modern GPUs. These packages \
|
|
provide only the common vendor-agnostic library loader, headers and \
|
|
the vulkaninfo utility."
|
|
HOMEPAGE = "https://www.khronos.org/vulkan/"
|
|
BUGTRACKER = "https://github.com/KhronosGroup/Vulkan-Loader"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=7dbefed23242760aa3475ee42801c5ac"
|
|
SRC_URI = "git://github.com/KhronosGroup/Vulkan-Loader.git;branch=master;protocol=https \
|
|
"
|
|
SRCREV = "1896143df69d439b0933c1bb485f5a4587bdf2dc"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
REQUIRED_DISTRO_FEATURES = "vulkan"
|
|
|
|
inherit cmake features_check
|
|
ANY_OF_DISTRO_FEATURES = "x11 wayland"
|
|
|
|
DEPENDS += "vulkan-headers"
|
|
|
|
EXTRA_OECMAKE = "\
|
|
-DBUILD_TESTS=OFF \
|
|
-DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
|
|
-DASSEMBLER_WORKS=FALSE \
|
|
-DVulkanHeaders_INCLUDE_DIR=${STAGING_INCDIR} \
|
|
-DVulkanRegistry_DIR=${RECIPE_SYSROOT}/${datadir} \
|
|
"
|
|
|
|
# must choose x11 or wayland or both
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[x11] = "-DBUILD_WSI_XLIB_SUPPORT=ON -DBUILD_WSI_XCB_SUPPORT=ON, -DBUILD_WSI_XLIB_SUPPORT=OFF -DBUILD_WSI_XCB_SUPPORT=OFF, libxcb libx11 libxrandr"
|
|
PACKAGECONFIG[wayland] = "-DBUILD_WSI_WAYLAND_SUPPORT=ON, -DBUILD_WSI_WAYLAND_SUPPORT=OFF, wayland"
|
|
|
|
RRECOMMENDS:${PN} = "mesa-vulkan-drivers"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "sdk-(?P<pver>\d+(\.\d+)+)"
|