mirror of
https://git.yoctoproject.org/poky
synced 2026-02-14 04:33:03 +01:00
641ba7069a
A number of features were disabled in OE due to historic problems on ARM. In tcf-agent 1.4, they compile cleanly on all architectures besides mips and libc-musl. These features are required for target debugging with Eclipse Neon, CDT and TCF plugins - for example used by Xilinx Vivado SDK 2016.4. For MIPS and libc-musl, at least re-enable SERVICE_Symbols and SERVICE_LineNumbers which compile cleanly. (From OE-Core rev: b07242cfe4544e99daf0a8d2f7062530e366bfae) Signed-off-by: Gernot Hillier <gernot.hillier@siemens.com> Signed-off-by: Tim Offermann <tim.offermann@siemens.com> Acked-by: Eugene Tarassov <eugene.tarassov@xilinx.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
2.2 KiB
BlitzBasic
58 lines
2.2 KiB
BlitzBasic
SUMMARY = "Target Communication Framework for the Eclipse IDE"
|
|
HOMEPAGE = "http://wiki.eclipse.org/TCF"
|
|
BUGTRACKER = "https://bugs.eclipse.org/bugs/"
|
|
|
|
LICENSE = "EPL-1.0 | EDL-1.0"
|
|
LIC_FILES_CHKSUM = "file://edl-v10.html;md5=522a390a83dc186513f0500543ad3679"
|
|
|
|
SRCREV = "2dddd5f440a15d5406032fac20f206484513646f"
|
|
PV = "1.4.0+git${SRCPV}"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>(\d+(\.\d+)+))"
|
|
SRC_URI = "git://git.eclipse.org/gitroot/tcf/org.eclipse.tcf.agent;branch=1.4_neon_bugfix \
|
|
file://fix_ranlib.patch \
|
|
file://ldflags.patch \
|
|
file://0001-canonicalize_file_name-is-specific-to-glibc.patch;striplevel=2 \
|
|
file://tcf-agent.init \
|
|
file://tcf-agent.service \
|
|
"
|
|
|
|
DEPENDS = "util-linux openssl"
|
|
RDEPENDS_${PN} = "bash"
|
|
|
|
S = "${WORKDIR}/git/agent"
|
|
|
|
inherit update-rc.d systemd
|
|
|
|
SYSTEMD_SERVICE_${PN} = "tcf-agent.service"
|
|
|
|
INITSCRIPT_NAME = "tcf-agent"
|
|
INITSCRIPT_PARAMS = "start 99 3 5 . stop 20 0 1 2 6 ."
|
|
|
|
# mangling needed for make
|
|
MAKE_ARCH = "`echo ${TARGET_ARCH} | sed s,i.86,i686, | sed s,aarch64,a64,`"
|
|
MAKE_OS = "`echo ${TARGET_OS} | sed s,^linux.*,GNU/Linux,`"
|
|
|
|
EXTRA_OEMAKE = "MACHINE=${MAKE_ARCH} OPSYS=${MAKE_OS} 'CC=${CC}' 'AR=${AR}'"
|
|
|
|
# These features don't compile on mips and libc-musl
|
|
CFLAGS_mips_append = "-DSERVICE_RunControl=0 -DSERVICE_Breakpoints=0 \
|
|
-DSERVICE_Memory=0 -DSERVICE_Registers=0 -DSERVICE_MemoryMap=0 \
|
|
-DSERVICE_StackTrace=0 -DSERVICE_Expressions=0"
|
|
CFLAGS_mips64_append = "-DSERVICE_RunControl=0 -DSERVICE_Breakpoints=0 \
|
|
-DSERVICE_Memory=0 -DSERVICE_Registers=0 -DSERVICE_MemoryMap=0 \
|
|
-DSERVICE_StackTrace=0 -DSERVICE_Expressions=0"
|
|
CFLAGS_append_libc-musl = "-DSERVICE_RunControl=0 -DSERVICE_Breakpoints=0 \
|
|
-DSERVICE_Memory=0 -DSERVICE_Registers=0 -DSERVICE_MemoryMap=0 \
|
|
-DSERVICE_StackTrace=0 -DSERVICE_Expressions=0"
|
|
|
|
do_install() {
|
|
oe_runmake install INSTALLROOT=${D}
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -m 0755 ${WORKDIR}/tcf-agent.init ${D}${sysconfdir}/init.d/tcf-agent
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${WORKDIR}/tcf-agent.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' ${D}${systemd_unitdir}/system/tcf-agent.service
|
|
}
|
|
|