mirror of
https://git.yoctoproject.org/poky
synced 2026-02-15 21:23:04 +01:00
eba78da9e0
(From OE-Core rev: 5fbdeddf45c423faa9139673e78812dbe9600cc7) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
36 lines
1.2 KiB
BlitzBasic
36 lines
1.2 KiB
BlitzBasic
DESCRIPTION = "C implementation of createrepo."
|
|
HOMEPAGE = "https://github.com/rpm-software-management/createrepo_c/wiki"
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
SRC_URI = "git://github.com/rpm-software-management/createrepo_c \
|
|
file://0001-Do-not-set-PYTHON_INSTALL_DIR-by-running-python.patch \
|
|
"
|
|
|
|
PV = "0.12.1"
|
|
SRCREV = "7744554ddef7c5be2cd7fbcac49c8b24ce60ef88"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
DEPENDS = "expat curl glib-2.0 libxml2 openssl bzip2 zlib file sqlite3 xz rpm"
|
|
DEPENDS_append_class-native = " file-replacement-native"
|
|
|
|
inherit cmake pkgconfig bash-completion distutils3-base
|
|
|
|
EXTRA_OECMAKE = " -DPYTHON_INSTALL_DIR=${PYTHON_SITEPACKAGES_DIR} -DPYTHON_DESIRED=3 -DWITH_ZCHUNK=OFF"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Direct createrepo to read rpm configuration from our sysroot, not the one it was compiled in
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/createrepo_c \
|
|
RPM_CONFIGDIR=${STAGING_LIBDIR_NATIVE}/rpm
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_wrapper ${D}/${bindir}/createrepo_c \
|
|
RPM_CONFIGDIR=${SDKPATHNATIVE}${libdir_nativesdk}/rpm
|
|
rm -rf ${D}/etc
|
|
}
|