mirror of
https://git.yoctoproject.org/poky
synced 2026-05-19 08:27:54 +02:00
ff525695f2
As stated in our top level license files, the license is MIT unless otherwise stated. Add SPDX identifers accordingly. Replace older license statementa with the standardised syntax. Also drop "All Rights Reserved" expression as it isn't used now, doesn't mean anything and is confusing. (From OE-Core rev: 081a391fe09a21265881e39a2a496e4e10b4f80b) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
30 lines
1.1 KiB
Plaintext
30 lines
1.1 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
# Gather existing and candidate postinst intercepts from BBPATH
|
|
POSTINST_INTERCEPTS_DIR ?= "${COREBASE}/scripts/postinst-intercepts"
|
|
POSTINST_INTERCEPTS_PATHS ?= "${@':'.join('%s/postinst-intercepts' % p for p in '${BBPATH}'.split(':'))}:${POSTINST_INTERCEPTS_DIR}"
|
|
|
|
python find_intercepts() {
|
|
intercepts = {}
|
|
search_paths = []
|
|
paths = d.getVar('POSTINST_INTERCEPTS_PATHS').split(':')
|
|
overrides = (':' + d.getVar('FILESOVERRIDES')).split(':') + ['']
|
|
search_paths = [os.path.join(p, op) for p in paths for op in overrides]
|
|
searched = oe.path.which_wild('*', ':'.join(search_paths), candidates=True)
|
|
files, chksums = [], []
|
|
for pathname, candidates in searched:
|
|
if os.path.isfile(pathname):
|
|
files.append(pathname)
|
|
chksums.append('%s:True' % pathname)
|
|
chksums.extend('%s:False' % c for c in candidates[:-1])
|
|
|
|
d.setVar('POSTINST_INTERCEPT_CHECKSUMS', ' '.join(chksums))
|
|
d.setVar('POSTINST_INTERCEPTS', ' '.join(files))
|
|
}
|
|
find_intercepts[eventmask] += "bb.event.RecipePreFinalise"
|
|
addhandler find_intercepts
|