mirror of
https://git.yoctoproject.org/poky
synced 2026-02-11 19:23:03 +01:00
ff525695f2
As stated in our top level license files, the license is MIT unless otherwise stated. Add SPDX identifers accordingly. Replace older license statementa with the standardised syntax. Also drop "All Rights Reserved" expression as it isn't used now, doesn't mean anything and is confusing. (From OE-Core rev: 081a391fe09a21265881e39a2a496e4e10b4f80b) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.3 KiB
Plaintext
41 lines
1.3 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
#
|
|
# Recipe needs to set MULTILIB_SCRIPTS in the form <pkgname>:<scriptname>, e.g.
|
|
# MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/file1 ${PN}:${base_bindir}/file2"
|
|
# to indicate which script files to process from which packages.
|
|
#
|
|
|
|
inherit update-alternatives
|
|
|
|
MULTILIB_SUFFIX = "${@d.getVar('base_libdir',1).split('/')[-1]}"
|
|
|
|
PACKAGE_PREPROCESS_FUNCS += "multilibscript_rename"
|
|
|
|
multilibscript_rename() {
|
|
:
|
|
}
|
|
|
|
python () {
|
|
# Do nothing if multilib isn't being used
|
|
if not d.getVar("MULTILIB_VARIANTS"):
|
|
return
|
|
# Do nothing for native/cross
|
|
if bb.data.inherits_class('native', d) or bb.data.inherits_class('cross', d):
|
|
return
|
|
|
|
for entry in (d.getVar("MULTILIB_SCRIPTS", False) or "").split():
|
|
pkg, script = entry.split(":")
|
|
epkg = d.expand(pkg)
|
|
scriptname = os.path.basename(script)
|
|
d.appendVar("ALTERNATIVE:" + epkg, " " + scriptname + " ")
|
|
d.setVarFlag("ALTERNATIVE_LINK_NAME", scriptname, script)
|
|
d.setVarFlag("ALTERNATIVE_TARGET", scriptname, script + "-${MULTILIB_SUFFIX}")
|
|
d.appendVar("multilibscript_rename", "\n mv ${PKGD}" + script + " ${PKGD}" + script + "-${MULTILIB_SUFFIX}")
|
|
d.appendVar("FILES:" + epkg, " " + script + "-${MULTILIB_SUFFIX}")
|
|
}
|