mirror of
https://git.yoctoproject.org/poky
synced 2026-04-28 06:32:34 +02:00
7fedc98498
libnotify only requires gtk+3 for its tests. Let's disable them by default and only enable them if "tests" is in PACKAGECONFIG. If gtk+3 is not available then we need to declare the dependency on gdk-pixbuf explicitly. It looks like the tests genuinely do need some sort of desktop environment to run, so let's maintain the ANY_OF_DISTRO_FEATURES check added back in 3edf08b38b0af93cef0933b061349264dc86d54c. (From OE-Core rev: da15d7cf3e6f31c92232f8dd7272ea9ee41656db) Signed-off-by: Mike Crowe <mac@mcrowe.com> Cc: Khem Raj <raj.khem@gmail.com> Cc: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.5 KiB
BlitzBasic
39 lines
1.5 KiB
BlitzBasic
SUMMARY = "Library for sending desktop notifications to a notification daemon"
|
|
DESCRIPTION = "It sends desktop notifications to a notification daemon, as defined \
|
|
in the Desktop Notifications spec. These notifications can be used to inform \
|
|
the user about an event or display some form of information without getting \
|
|
in the user's way."
|
|
HOMEPAGE = "https://gitlab.gnome.org/GNOME/libnotify"
|
|
BUGTRACKER = "https://gitlab.gnome.org/GNOME/libnotify/issues"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPLv2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=7fbc338309ac38fefcd64b04bb903e34"
|
|
|
|
DEPENDS = "dbus glib-2.0 gdk-pixbuf"
|
|
|
|
PACKAGECONFIG ?= ""
|
|
PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,gtk+3"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
GIR_MESON_ENABLE_FLAG = "enabled"
|
|
GIR_MESON_DISABLE_FLAG = "disabled"
|
|
inherit gnomebase gtk-doc features_check gobject-introspection
|
|
# depends on gtk+3 if tests are enabled
|
|
ANY_OF_DISTRO_FEATURES = "${@bb.utils.contains('PACKAGECONFIG', 'tests', '${GTK3DISTROFEATURES}', '', d)}"
|
|
|
|
SRC_URI[archive.md5sum] = "ccd9c53364174cc8d13e18a1988faa76"
|
|
SRC_URI[archive.sha256sum] = "66c0517ed16df7af258e83208faaf5069727dfd66995c4bbc51c16954d674761"
|
|
|
|
EXTRA_OEMESON = "-Dman=false"
|
|
|
|
# there were times, we had two versions of libnotify (oe-core libnotify:0.6.x /
|
|
# meta-gnome libnotify3: 0.7.x)
|
|
PROVIDES += "libnotify3"
|
|
RPROVIDES_${PN} += "libnotify3"
|
|
RCONFLICTS_${PN} += "libnotify3"
|
|
RREPLACES_${PN} += "libnotify3"
|
|
|
|
# -7381 is specific to the NodeJS bindings
|
|
CVE_CHECK_WHITELIST += "CVE-2013-7381"
|