mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 09:32:11 +02:00
0b10203499
file will automatically enable seccomp if the seccomp headers are available, but the build will fail on Opensuse Tumbleweed because the include paths are wrong. Enabling seccomp is a bad idea because it interacts badly with pseudo (causing build failures), so explicitly and globally disable seccomp. (From OE-Core rev: cbbbee1dce84d6ff62fb72282088f839cb642857) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit a752faa152df031df5acaa40491299ac115109a4) Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.5 KiB
BlitzBasic
49 lines
1.5 KiB
BlitzBasic
SUMMARY = "File classification tool"
|
|
DESCRIPTION = "File attempts to classify files depending \
|
|
on their contents and prints a description if a match is found."
|
|
HOMEPAGE = "http://www.darwinsys.com/file/"
|
|
SECTION = "console/utils"
|
|
|
|
# two clause BSD
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=2;md5=0251eaec1188b20d9a72c502ecfdda1b"
|
|
|
|
DEPENDS = "zlib file-replacement-native"
|
|
DEPENDS_class-native = "zlib-native"
|
|
|
|
# Blacklist a bogus tag in upstream check
|
|
UPSTREAM_CHECK_GITTAGREGEX = "FILE(?P<pver>(?!6_23).+)"
|
|
|
|
SRC_URI = "git://github.com/file/file.git"
|
|
|
|
SRCREV = "a0d5b0e4e9f97d74a9911e95cedd579852e25398"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
EXTRA_OECONF += "--disable-libseccomp"
|
|
|
|
ALTERNATIVE_${PN} = "file"
|
|
ALTERNATIVE_LINK_NAME[file] = "${bindir}/file"
|
|
|
|
EXTRA_OEMAKE_append_class-target = "-e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
EXTRA_OEMAKE_append_class-nativesdk = "-e FILE_COMPILE=${STAGING_BINDIR_NATIVE}/file-native/file"
|
|
|
|
FILES_${PN} += "${datadir}/misc/*.mgc"
|
|
|
|
do_install_append_class-native() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
do_install_append_class-nativesdk() {
|
|
create_cmdline_wrapper ${D}/${bindir}/file \
|
|
--magic-file ${datadir}/misc/magic.mgc
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
PROVIDES_append_class-native = " file-replacement-native"
|
|
# Don't use NATIVE_PACKAGE_PATH_SUFFIX as that hides libmagic from anyone who
|
|
# depends on file-replacement-native.
|
|
bindir_append_class-native = "/file-native"
|