mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 15:32:13 +02:00
552525cd67
Bumping lttng-modules to version v2.13.9-4-g12f43cab, which comprises the following commits:
da1f5a26 Version 2.13.9
dc2d1294 fix: jbd2: use the correct print format (v5.4.229)
d04c1211 fix: jbd2 upper bound for v5.10.163
4b8864fc fix: jbd2: use the correct print format (v5.10.163)
69d3aa79 fix: btrfs: move accessor helpers into accessors.h (v6.2)
We drop our previously backported commits as well, since they are part
of the release.
(From OE-Core rev: 8864e50267327b474806de8b12ec60137a3cf17b)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
(cherry picked from commit 79d8e93adde07ff3a4a239d66649ee566a2437d6)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.6 KiB
BlitzBasic
43 lines
1.6 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
HOMEPAGE = "https://lttng.org/"
|
|
LICENSE = "LGPL-2.1-only & GPL-2.0-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=0464cff101a009c403cd2ed65d01d4c4"
|
|
|
|
inherit module
|
|
|
|
include lttng-platforms.inc
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://0009-Rename-genhd-wrapper-to-blkdev.patch \
|
|
"
|
|
|
|
# Use :append here so that the patch is applied also when using devupstream
|
|
SRC_URI:append = " file://0001-src-Kbuild-change-missing-CONFIG_TRACEPOINTS-to-warn.patch"
|
|
|
|
SRC_URI[sha256sum] = "bf808b113544287cfe837a6382887fa66354ef5cc8216460cebbef3d27dc3581"
|
|
|
|
export INSTALL_MOD_DIR="kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
MODULES_MODULE_SYMVERS_LOCATION = "src"
|
|
|
|
do_install:append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
if [ -d ${D}/${nonarch_base_libdir} ]; then
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
fi
|
|
}
|
|
|
|
python do_package:prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRC_URI:class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.13"
|
|
SRCREV:class-devupstream = "7584cfc04914cb0842a986e9808686858b9c8630"
|
|
SRCREV_FORMAT ?= "lttng_git"
|