mirror of
https://git.yoctoproject.org/poky
synced 2026-05-05 07:39:49 +02:00
689097cdf3
* with many native dependencies excluded in: layer.conf: Extend recipes not to install without explict dependencies this was now failing with: ERROR: Cannot find Ninja and after adding ninja-native to DEPENDS it was failing due to missing meson as well: /OE/build/oe-core/tmp-glibc/work/x86_64-linux/qemu-native/6.0.0-r0/qemu-6.0.0/configure: 6415: --version: not found /OE/build/oe-core/tmp-glibc/work/x86_64-linux/qemu-native/6.0.0-r0/qemu-6.0.0/configure: 6418: setup: not found (From OE-Core rev: 7b2dfb49105e6465c5436869863e6a9720c60bbd) Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
32 lines
1.1 KiB
BlitzBasic
32 lines
1.1 KiB
BlitzBasic
BPN = "qemu"
|
|
|
|
inherit python3-dir
|
|
|
|
require qemu-native.inc
|
|
|
|
# As some of the files installed by qemu-native and qemu-system-native
|
|
# are the same, we depend on qemu-native to get the full installation set
|
|
# and avoid file clashes
|
|
DEPENDS = "glib-2.0-native zlib-native pixman-native qemu-native bison-native meson-native ninja-native"
|
|
|
|
EXTRA_OECONF:append = " --target-list=${@get_qemu_system_target_list(d)}"
|
|
|
|
PACKAGECONFIG ??= "fdt alsa kvm pie \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer glx', '', d)} \
|
|
"
|
|
|
|
# Handle distros such as CentOS 5 32-bit that do not have kvm support
|
|
PACKAGECONFIG:remove = "${@'kvm' if not os.path.exists('/usr/include/linux/kvm.h') else ''}"
|
|
|
|
do_install:append() {
|
|
install -Dm 0755 ${WORKDIR}/powerpc_rom.bin ${D}${datadir}/qemu
|
|
|
|
# The following is also installed by qemu-native
|
|
rm -f ${D}${datadir}/qemu/trace-events-all
|
|
rm -rf ${D}${datadir}/qemu/keymaps
|
|
rm -rf ${D}${datadir}/icons/
|
|
|
|
# Install qmp.py to be used with testimage
|
|
install -D ${S}/python/qemu/qmp.py ${D}${PYTHON_SITEPACKAGES_DIR}/qmp.py
|
|
}
|