mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 08:48:45 +01:00
af85ce4b4e
Remove layout_* variables and replace them with variables specific to the different classes. The layout variables were only useful for the native/cross classes and caused more confusion than they solved. They didn't scale to the sdk class. It now clear a small set of native/cross variables fulfil the needs. This patch also changes native.bbclass to use "/" as the STAGING_DIR which makes sense since we're installing binaries into the locations we're compiling them for. Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>
56 lines
2.0 KiB
Plaintext
56 lines
2.0 KiB
Plaintext
# The namespaces can clash here hence the two step replace
|
|
def get_binconfig_mangle(d):
|
|
import bb.data
|
|
s = "-e ''"
|
|
if not bb.data.inherits_class('native', d):
|
|
optional_quote = r"\(\"\?\)"
|
|
s += " -e 's:=%s${libdir}:=\\1OELIBDIR:;'" % optional_quote
|
|
s += " -e 's:=%s${includedir}:=\\1OEINCDIR:;'" % optional_quote
|
|
s += " -e 's:=%s${datadir}:=\\1OEDATADIR:'" % optional_quote
|
|
s += " -e 's:=%s${prefix}:=\\1OEPREFIX:'" % optional_quote
|
|
s += " -e 's:=%s${exec_prefix}:=\\1OEEXECPREFIX:'" % optional_quote
|
|
s += " -e 's:-L${libdir}:-LOELIBDIR:;'"
|
|
s += " -e 's:-I${includedir}:-IOEINCDIR:;'"
|
|
s += " -e 's:OELIBDIR:${STAGING_LIBDIR}:;'"
|
|
s += " -e 's:OEINCDIR:${STAGING_INCDIR}:;'"
|
|
s += " -e 's:OEDATADIR:${STAGING_DATADIR}:'"
|
|
s += " -e 's:OEPREFIX:${STAGING_DIR_HOST}${prefix}:'"
|
|
s += " -e 's:OEEXECPREFIX:${STAGING_DIR_HOST}${exec_prefix}:'"
|
|
s += " -e 's:-I${WORKDIR}:-I${STAGING_INCDIR}:'"
|
|
s += " -e 's:-L${WORKDIR}:-L${STAGING_LIBDIR}:'"
|
|
return s
|
|
|
|
BINCONFIG_GLOB ?= "*-config"
|
|
|
|
do_install_append() {
|
|
|
|
#the 'if' protects native packages, since we can't easily check for bb.data.inherits_class('native', d) in shell
|
|
if [ -e ${D}${bindir} ] ; then
|
|
for config in `find ${S} -name '${BINCONFIG_GLOB}'`; do
|
|
cat $config | sed \
|
|
-e 's:${STAGING_LIBDIR}:${libdir}:g;' \
|
|
-e 's:${STAGING_INCDIR}:${includedir}:g;' \
|
|
-e 's:${STAGING_DATADIR}:${datadir}:' \
|
|
-e 's:${STAGING_DIR_HOST}${prefix}:${prefix}:' > ${D}${bindir}/`basename $config`
|
|
done
|
|
fi
|
|
|
|
for lafile in `find ${D} -name *.la` ; do
|
|
sed -i \
|
|
-e 's:${STAGING_LIBDIR}:${libdir}:g;' \
|
|
-e 's:${STAGING_INCDIR}:${includedir}:g;' \
|
|
-e 's:${STAGING_DATADIR}:${datadir}:' \
|
|
-e 's:${STAGING_DIR_HOST}${prefix}:${prefix}:' \
|
|
$lafile
|
|
done
|
|
}
|
|
|
|
do_stage_append() {
|
|
for config in `find ${S} -name '${BINCONFIG_GLOB}'`; do
|
|
configname=`basename $config`
|
|
install -d ${STAGING_BINDIR_CROSS}
|
|
cat $config | sed ${@get_binconfig_mangle(d)} > ${STAGING_BINDIR_CROSS}/$configname
|
|
chmod u+x ${STAGING_BINDIR_CROSS}/$configname
|
|
done
|
|
}
|