mirror of
https://git.yoctoproject.org/poky
synced 2026-02-27 03:49:41 +01:00
292471701b
The perl distribution "XML-Parser" relies for configuration
on the tooling of Devel::CheckLib - which is not aware of
sysroot locations nor of reasonable compiler/link definitions
from outside.
This causes
ERROR: libxml-parser-perl-2.44-r0 do_package_qa: QA Issue: package libxml-parser-perl contains bad RPATH ${BUILDDIR}/tmp/work/core2-64-poky-linux/libxml-parser-perl/2.44-r0/recipe-sysroot/usr/lib in file ${BUILDDIR}/tmp/work/core2-64-poky-linux/libxml-parser-perl/2.44-r0/packages-split/libxml-parser-perl/usr/lib/perl/vendor_perl/5.24.4/auto/XML/Parser/Expat/Expat.so
package libxml-parser-perl contains bad RPATH ${BUILDDIR}/tmp/work/core2-64-poky-linux/libxml-parser-perl/2.44-r0/recipe-sysroot/usr/lib in file ${BUILDDIR}/tmp/work/core2-64-poky-linux/libxml-parser-perl/2.44-r0/packages-split/libxml-parser-perl/usr/lib/perl/vendor_perl/5.24.4/auto/XML/Parser/Expat/Expat.so [rpaths]
ERROR: libxml-parser-perl-2.44-r0 do_package_qa: QA run found fatal errors. Please consider fixing them.
ERROR: libxml-parser-perl-2.44-r0 do_package_qa: Function failed: do_package_qa
It's strongly encouraged to the maintainer @toddr to rework the
toolchain for up to date environments.
[RP: Added fix for nativesdk RPATH issues too]
(From OE-Core rev: b103bb9426c0e5e3ef0fe0c34274ad3a06af8b6a)
Signed-off-by: Jens Rehsack <sno@netbsd.org>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
61 lines
2.0 KiB
BlitzBasic
61 lines
2.0 KiB
BlitzBasic
SUMMARY = "XML::Parser - A perl module for parsing XML documents"
|
|
HOMEPAGE = "https://libexpat.github.io/"
|
|
SECTION = "libs"
|
|
LICENSE = "Artistic-1.0 | GPL-1.0+"
|
|
LIC_FILES_CHKSUM = "file://README;beginline=2;endline=6;md5=c8767d7516229f07b26e42d1cf8b51f1"
|
|
|
|
DEPENDS += "expat"
|
|
|
|
SRC_URI = "http://www.cpan.org/modules/by-module/XML/XML-Parser-${PV}.tar.gz"
|
|
SRC_URI[md5sum] = "af4813fe3952362451201ced6fbce379"
|
|
SRC_URI[sha256sum] = "1ae9d07ee9c35326b3d9aad56eae71a6730a73a116b9fe9e8a4758b7cc033216"
|
|
|
|
S = "${WORKDIR}/XML-Parser-${PV}"
|
|
|
|
EXTRA_CPANFLAGS = "EXPATLIBPATH=${STAGING_LIBDIR} EXPATINCPATH=${STAGING_INCDIR} CC='${CC}' LD='${CCLD}' FULL_AR='${AR}'"
|
|
|
|
inherit cpan ptest-perl
|
|
|
|
# fix up sub MakeMaker project as arguments don't get propagated though
|
|
# see https://rt.cpan.org/Public/Bug/Display.html?id=28632
|
|
do_configure_append_class-target() {
|
|
sed -E \
|
|
-e 's:-L${STAGING_LIBDIR}::g' -e 's:-I${STAGING_INCDIR}::g' \
|
|
-e 's:LD_RUN_PATH ?= ?"?[^"]*"?::g' \
|
|
-i Makefile Expat/Makefile
|
|
}
|
|
|
|
do_configure_append_class-nativesdk() {
|
|
sed -E \
|
|
-e 's:LD_RUN_PATH ?= ?"?[^"]*"?::g' \
|
|
-i Makefile Expat/Makefile
|
|
}
|
|
|
|
do_configure_append() {
|
|
sed -e 's:--sysroot=.*\(\s\|$\):--sysroot=${STAGING_DIR_TARGET} :g' \
|
|
-i Makefile Expat/Makefile
|
|
sed 's:^FULL_AR = .*:FULL_AR = ${AR}:g' -i Expat/Makefile
|
|
# make sure these two do not build in parallel
|
|
sed 's!^$(INST_DYNAMIC):!$(INST_DYNAMIC): $(BOOTSTRAP)!' -i Expat/Makefile
|
|
}
|
|
|
|
do_compile() {
|
|
export LIBC="$(find ${STAGING_DIR_TARGET}/${base_libdir}/ -name 'libc-*.so')"
|
|
cpan_do_compile
|
|
}
|
|
|
|
do_compile_class-native() {
|
|
cpan_do_compile
|
|
}
|
|
|
|
do_install_ptest() {
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/xmlstats
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/xmlfilter
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/xmlcomments
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/canonical
|
|
cp -r ${B}/samples ${D}${PTEST_PATH}
|
|
chown -R root:root ${D}${PTEST_PATH}/samples
|
|
}
|
|
|
|
BBCLASSEXTEND="native nativesdk"
|