mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 04:19:40 +01:00
5f469434d3
There are new CVEs reported for this recipe which are not for this componene, but for a component with same name from apache. sqlite> select vendor, product, id, count(*) from products where product like 'orc' group by vendor, product, id; apache|orc|CVE-2018-8015|1 apache|orc|CVE-2025-47436|4 gstreamer|orc|CVE-2024-40897|1 (From OE-Core rev: f5e320c0ea57ce1813ed09da703fe2b33f4976e6) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Steve Sakoman <steve@sakoman.com>
34 lines
1.2 KiB
BlitzBasic
34 lines
1.2 KiB
BlitzBasic
SUMMARY = "Optimised Inner Loop Runtime Compiler"
|
|
HOMEPAGE = "http://gstreamer.freedesktop.org/modules/orc.html"
|
|
DESCRIPTION = "Optimised Inner Loop Runtime Compiler is a Library and set of tools for compiling and executing SIMD assembly language-like programs that operate on arrays of data."
|
|
LICENSE = "BSD-2-Clause & BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1400bd9d09e8af56b9ec982b3d85797e"
|
|
|
|
SRC_URI = "http://gstreamer.freedesktop.org/src/orc/orc-${PV}.tar.xz"
|
|
SRC_URI[sha256sum] = "3fc2bee78dfb7c41fd9605061fc69138db7df007eae2f669a1f56e8bacef74ab"
|
|
|
|
inherit meson pkgconfig gtk-doc
|
|
|
|
# distinguish from apache:orc
|
|
CVE_PRODUCT = "gstreamer:orc"
|
|
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
GTKDOC_MESON_ENABLE_FLAG = "enabled"
|
|
GTKDOC_MESON_DISABLE_FLAG = "disabled"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
PACKAGES =+ "orc-examples"
|
|
PACKAGES_DYNAMIC += "^liborc-.*"
|
|
FILES:orc-examples = "${libdir}/orc/*"
|
|
FILES:${PN} = "${bindir}/*"
|
|
|
|
python populate_packages:prepend () {
|
|
libdir = d.expand('${libdir}')
|
|
do_split_packages(d, libdir, r'^lib(.*)\.so\.*', 'lib%s', 'ORC %s library', extra_depends='', allow_links=True)
|
|
}
|
|
|
|
do_compile:prepend:class-native () {
|
|
sed -i -e 's#/tmp#.#g' ${S}/orc/orccodemem.c
|
|
}
|