mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
ddd907e591
Switch to downloading the release tarballs from GitHub. Their CDN is rock solid, and strace.io is hosted inside Russia which some networks are blocking. (From OE-Core rev: 0ed862a612af7a6389e68cdcb2e94bd005bf64c2) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit bbdbd6d943a64e5b0dae4c2ee705d017fb7ef80e) Signed-off-by: Steve Sakoman <steve@sakoman.com>
57 lines
2.3 KiB
BlitzBasic
57 lines
2.3 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.io"
|
|
DESCRIPTION = "strace is a diagnostic, debugging and instructional userspace utility for Linux. It is used to monitor and tamper with interactions between processes and the Linux kernel, which include system calls, signal deliveries, and changes of process state."
|
|
SECTION = "console/utils"
|
|
LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2433d82e1432a76dc3eadd9002bfe304"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/strace-${PV}.tar.xz \
|
|
file://update-gawk-paths.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://ptest-spacesave.patch \
|
|
file://0001-strace-fix-reproducibilty-issues.patch \
|
|
file://skip-load.patch \
|
|
file://0001-configure-Use-autoconf-macro-to-detect-largefile-sup.patch \
|
|
file://0002-tests-Replace-off64_t-with-off_t.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "2090201e1a3ff32846f4fe421c1163b15f440bb38e31355d09f82d3949922af7"
|
|
|
|
inherit autotools github-releases ptest
|
|
|
|
# Not yet ported to rv32
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
# bluez is not enabled by default due to build dependency creep in smaller builds
|
|
# like core-image-minimal leading to significantly more tasks being executed
|
|
PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
|
|
|
|
EXTRA_OECONF += "--enable-mpers=no --disable-gcc-Werror"
|
|
|
|
CFLAGS:append:libc-musl = " -Dsigcontext_struct=sigcontext"
|
|
|
|
TESTDIR = "tests"
|
|
PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
mkdir -p ${D}${PTEST_PATH}/build-aux
|
|
mkdir -p ${D}${PTEST_PATH}/src
|
|
install -m 755 ${S}/build-aux/test-driver ${D}${PTEST_PATH}/build-aux/
|
|
install -m 644 ${B}/src/config.h ${D}${PTEST_PATH}/src/
|
|
sed -i -e '/^src/s/strace.*[0-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += "make coreutils grep gawk sed"
|
|
|
|
RDEPENDS:${PN}-ptest:append:libc-glibc = "\
|
|
locale-base-en-us.iso-8859-1 \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native"
|