mirror of
https://git.yoctoproject.org/poky
synced 2026-02-12 03:33:02 +01:00
8c5e589df8
rust-cross-* imported from meta-rust has incorrect signatures, depending on MACHINEOVERRIDES making it effectively MACHINE_ARCH as shown by sstate-diff-machines.sh: openembedded-core/scripts/sstate-diff-machines.sh --tmpdir=tmp-glibc \ --machines="qemuarm64 qemuarm64copy" --targets=rust-cross-aarch64-glibc \ --analyze === Comparing signatures for task do_configure.sigdata between qemuarm64 and qemuarm64copy === ERROR: gcc-runtime different signature for task do_configure.sigdata between qemuarm64 and qemuarm64copy NOTE: Starting bitbake server... Hash for dependent task gcc/gcc-runtime_11.2.bb:do_prepare_recipe_sysroot changed from da4ebf1b272cb73153145a0a95e6438d2955ae2d36f84db10f6880b2781ec331 to 47a0ebb7a88c9f896fb9dbce269f575ab8a6faabb2b9e62d164be6e71c5e4e40 Unable to find matching sigdata for openembedded-core/meta/recipes-devtools/gcc/gcc-runtime_11.2.bb: do_prepare_recipe_sysroot with hashes da4ebf1b272cb73153145a0a95e6438d2955ae2d36f84db10f6880b2781ec331 or 47a0ebb7a88c9f896fb9dbce269f575ab8a6faabb2b9e62d164be6e71c5e4e40 The following patch takes TUNE_PKGARCH into consideration instead of TARGET_ARCH and results in signatures as expected. [YOCTO #14613] RP: Added maintainer.inc corresponding change (From OE-Core rev: bcf48766d1123cea41f80b0cb687584692c96158) Signed-off-by: Pgowda <pgowda.cve@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
74 lines
2.8 KiB
PHP
74 lines
2.8 KiB
PHP
require rust.inc
|
|
inherit cross
|
|
|
|
python do_rust_gen_targets () {
|
|
wd = d.getVar('WORKDIR') + '/targets/'
|
|
# It is important 'TARGET' is last here so that it overrides our less
|
|
# informed choices for BUILD & HOST if TARGET happens to be the same as
|
|
# either of them.
|
|
for thing in ['BUILD', 'HOST', 'TARGET']:
|
|
bb.debug(1, "rust_gen_target for " + thing)
|
|
features = ""
|
|
cpu = "generic"
|
|
arch = d.getVar('{}_ARCH'.format(thing))
|
|
abi = ""
|
|
if thing is "TARGET":
|
|
abi = d.getVar('ABIEXTENSION')
|
|
# arm and armv7 have different targets in llvm
|
|
if arch == "arm" and target_is_armv7(d):
|
|
arch = 'armv7'
|
|
features = d.getVar('TARGET_LLVM_FEATURES') or ""
|
|
cpu = d.getVar('TARGET_LLVM_CPU')
|
|
rust_gen_target(d, thing, wd, features, cpu, arch, abi)
|
|
}
|
|
|
|
# Otherwise we'll depend on what we provide
|
|
INHIBIT_DEFAULT_RUST_DEPS = "1"
|
|
|
|
# Unlike native (which nicely maps it's DEPENDS) cross wipes them out completely.
|
|
# Generally, we (and cross in general) need the same things that native needs,
|
|
# so it might make sense to take it's mapping. For now, though, we just mention
|
|
# the bits we need explicitly.
|
|
DEPENDS += "rust-llvm-native"
|
|
DEPENDS += "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}compilerlibs virtual/libc"
|
|
DEPENDS += "rust-native"
|
|
|
|
PROVIDES = "virtual/${TARGET_PREFIX}rust"
|
|
PN = "rust-cross-${TUNE_PKGARCH}-${TCLIBC}"
|
|
|
|
# In the cross compilation case, rustc doesn't seem to get the rpath quite
|
|
# right. It manages to include '../../lib/${TARGET_PREFIX}', but doesn't
|
|
# include the '../../lib' (ie: relative path from cross_bindir to normal
|
|
# libdir. As a result, we end up not being able to properly reference files in normal ${libdir}.
|
|
# Most of the time this happens to work fine as the systems libraries are
|
|
# subsituted, but sometimes a host system will lack a library, or the right
|
|
# version of a library (libtinfo was how I noticed this).
|
|
#
|
|
# FIXME: this should really be fixed in rust itself.
|
|
# FIXME: using hard-coded relative paths is wrong, we should ask bitbake for
|
|
# the relative path between 2 of it's vars.
|
|
HOST_POST_LINK_ARGS:append = " -Wl,-rpath=../../lib"
|
|
BUILD_POST_LINK_ARGS:append = " -Wl,-rpath=../../lib"
|
|
|
|
# We need the same thing for the calls to the compiler when building the runtime crap
|
|
TARGET_CC_ARCH:append = " --sysroot=${STAGING_DIR_TARGET}"
|
|
|
|
do_rust_setup_snapshot () {
|
|
}
|
|
|
|
do_configure () {
|
|
}
|
|
|
|
do_compile () {
|
|
}
|
|
|
|
do_install () {
|
|
mkdir -p ${D}${prefix}/${base_libdir_native}/rustlib
|
|
cp ${WORKDIR}/targets/${TARGET_SYS}.json ${D}${prefix}/${base_libdir_native}/rustlib
|
|
}
|
|
|
|
rust_cross_sysroot_preprocess() {
|
|
sysroot_stage_dir ${D}${prefix}/${base_libdir_native}/rustlib ${SYSROOT_DESTDIR}${prefix}/${base_libdir_native}/rustlib
|
|
}
|
|
SYSROOT_PREPROCESS_FUNCS += "rust_cross_sysroot_preprocess"
|