mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 02:33:02 +01:00
49f05afa7f
This commits fixes these packaging warnings WARNING: For recipe git, the following files/directories were installed but not shipped in any package: WARNING: /usr/lib/perl-native WARNING: /usr/lib/perl-native/perl WARNING: /usr/lib/perl-native/perl/5.14.2 WARNING: /usr/lib/perl-native/perl/5.14.2/Git.pm WARNING: /usr/lib/perl-native/perl/5.14.2/perllocal.pod WARNING: /usr/lib/perl-native/perl/5.14.2/auto WARNING: /usr/lib/perl-native/perl/5.14.2/auto/Git WARNING: /usr/lib/perl-native/perl/5.14.2/auto/Git/.packlist PR not bumped because no change in the output packages. (From OE-Core rev: b2dcb79c8c713ffb25d49a355fdb1bfa97d3c10d) Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
66 lines
1.9 KiB
PHP
66 lines
1.9 KiB
PHP
DESCRIPTION = "The git revision control system used by the Linux kernel developers"
|
|
SECTION = "console/utils"
|
|
LICENSE = "GPLv2"
|
|
DEPENDS = "openssl curl zlib expat"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/scm/git/git-${PV}.tar.bz2 "
|
|
S = "${WORKDIR}/git-${PV}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=7c0d7ef03a7eb04ce795b0f60e68e7e1"
|
|
|
|
EXTRA_OECONF = "--with-perl=${STAGING_BINDIR_NATIVE}/perl-native/perl --without-tcltk"
|
|
|
|
inherit autotools perlnative
|
|
|
|
do_install () {
|
|
oe_runmake install DESTDIR="${D}" bindir=${bindir} \
|
|
template_dir=${datadir}/git-core/templates \
|
|
GIT_PYTHON_DIR=${D}${datadir}/git-core/python
|
|
rm -rf ${D}${libdir}/perl-native
|
|
}
|
|
|
|
do_install_append_virtclass-native() {
|
|
create_wrapper ${D}/${bindir}/git \
|
|
GIT_EXEC_PATH=${libexecdir}/git-core \
|
|
GIT_TEMPLATE_DIR=${STAGING_DATADIR_NATIVE}/git-core/templates
|
|
}
|
|
|
|
FILES_${PN} += "${datadir}/git-core ${libxecdir}/git-core/"
|
|
FILES_${PN}-dbg += "${libexecdir}/git-core/.debug"
|
|
|
|
# Git tools requiring perl
|
|
PACKAGES =+ "${PN}-perltools"
|
|
FILES_${PN}-perltools += " \
|
|
${libexecdir}/git-core/git-add--interactive \
|
|
${libexecdir}/git-core/git-archimport \
|
|
${libexecdir}/git-core/git-cvsexportcommit \
|
|
${libexecdir}/git-core/git-cvsimport \
|
|
${libexecdir}/git-core/git-cvsserver \
|
|
${bindir}/git-cvsserver \
|
|
${libexecdir}/git-core/git-difftool \
|
|
${libexecdir}/git-core/git-relink \
|
|
${libexecdir}/git-core/git-send-email \
|
|
${libexecdir}/git-core/git-svn \
|
|
${datadir}/perl \
|
|
"
|
|
RDEPENDS_${PN}-perltools = "${PN} perl perl-module-file-path findutils"
|
|
|
|
PACKAGES =+ "${PN}-python"
|
|
FILES_${PN}-python = "${libdir}/python*"
|
|
|
|
|
|
# git-tk package with gitk and git-gui
|
|
PACKAGES =+ "${PN}-tk"
|
|
#RDEPENDS_${PN}-tk = "${PN} tk tcl"
|
|
#EXTRA_OEMAKE = "TCL_PATH=${STAGING_BINDIR_CROSS}/tclsh"
|
|
FILES_${PN}-tk = " \
|
|
${bindir}/gitk \
|
|
${datadir}/gitk \
|
|
"
|
|
|
|
PACKAGES =+ "gitweb"
|
|
FILES_gitweb = "${datadir}/gitweb/"
|
|
|
|
|
|
BBCLASSEXTEND = "native"
|