mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
29d6678fd5
Having one monolithic packages directory makes it hard to find things and is generally overwhelming. This commit splits it into several logical sections roughly based on function, recipes.txt gives more information about the classifications used. The opportunity is also used to switch from "packages" to "recipes" as used in OpenEmbedded as the term "packages" can be confusing to people and has many different meanings. Not all recipes have been classified yet, this is just a first pass at separating things out. Some packages are moved to meta-extras as they're no longer actively used or maintained. Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>
56 lines
2.0 KiB
BlitzBasic
56 lines
2.0 KiB
BlitzBasic
DESCRIPTION = "This package provides the necessary infrastructure for basic TCP/IP based networking"
|
|
HOMEPAGE = "http://packages.debian.org/netbase"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2"
|
|
PR = "r0"
|
|
|
|
inherit update-rc.d
|
|
|
|
INITSCRIPT_NAME = "networking"
|
|
INITSCRIPT_PARAMS = "start 40 S . stop 40 0 6 1 ."
|
|
# On MNCI etc, start very late so that our own apps come up faster
|
|
INITSCRIPT_PARAMS_openmn = "start 85 1 2 3 4 5 . stop 85 0 6 1 ."
|
|
# On SlugOS (NSLU2) delay the stop until after network apps have exited
|
|
# Do not stop in single user - there's no way to sulogin!
|
|
INITSCRIPT_PARAMS_slugos = "start 42 S 0 6 ."
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/n/netbase/netbase_${PV}.tar.gz \
|
|
file://init \
|
|
file://hosts \
|
|
file://interfaces \
|
|
file://nfsroot"
|
|
|
|
do_install () {
|
|
install -d ${D}${sysconfdir}/init.d \
|
|
${D}${sbindir} \
|
|
${D}${mandir}/man8 \
|
|
${D}${sysconfdir}/network/if-pre-up.d \
|
|
${D}${sysconfdir}/network/if-up.d \
|
|
${D}${sysconfdir}/network/if-down.d \
|
|
${D}${sysconfdir}/network/if-post-down.d
|
|
install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/networking
|
|
install -m 0644 ${WORKDIR}/hosts ${D}${sysconfdir}/hosts
|
|
install -m 0644 etc-rpc ${D}${sysconfdir}/rpc
|
|
install -m 0644 etc-protocols ${D}${sysconfdir}/protocols
|
|
install -m 0644 etc-services ${D}${sysconfdir}/services
|
|
install -m 0644 ${WORKDIR}/interfaces ${D}${sysconfdir}/network/interfaces
|
|
install -m 0755 ${WORKDIR}/nfsroot ${D}${sysconfdir}/network/if-pre-up.d
|
|
|
|
# Disable network manager on machines that commonly do NFS booting
|
|
case "${MACHINE}" in
|
|
"omap-3430sdp" | "omap-3430ldp" | "omap-2430sdp" | "qemuarm" | "qemux86" )
|
|
touch ${D}${sysconfdir}/network/nm-disabled-eth0
|
|
;;
|
|
*)
|
|
;;
|
|
esac
|
|
}
|
|
|
|
CONFFILES_${PN} = "${sysconfdir}/hosts ${sysconfdir}/network/interfaces"
|
|
|
|
PACKAGE_ARCH_omap-3430sdp = "${MACHINE_ARCH}"
|
|
PACKAGE_ARCH_omap-3430ldp = "${MACHINE_ARCH}"
|
|
PACKAGE_ARCH_omap-2430sdp = "${MACHINE_ARCH}"
|
|
PACKAGE_ARCH_qemuarm = "${MACHINE_ARCH}"
|
|
PACKAGE_ARCH_qemux86 = "${MACHINE_ARCH}"
|