mirror of
https://git.yoctoproject.org/poky
synced 2026-05-01 15:32:12 +02:00
64df4e4aef
The class itself currently does nothing. The idea is to mark all recipes that make use of the texinfo utilities. In the future, this class could be used to suppress the generation/formatting of documentation for performance, explicitly track dependencies on these utilities, and eliminate Yocto's current dependency on the host system's texinfo utilities. (From OE-Core rev: e6fb2f9afe2ba6b676c46d1eb297ca9cc532d405) Signed-off-by: Max Eliaser <max.eliaser@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.5 KiB
BlitzBasic
53 lines
1.5 KiB
BlitzBasic
SUMMARY = "GNU awk text processing utility"
|
|
DESCRIPTION = "The GNU version of awk, a text processing utility. \
|
|
Awk interprets a special-purpose programming language to do \
|
|
quick and easy text pattern matching and reformatting jobs."
|
|
HOMEPAGE = "www.gnu.org/software/gawk"
|
|
BUGTRACKER = "bug-gawk@gnu.org"
|
|
SECTION = "console/utils"
|
|
|
|
# gawk <= 3.1.5: GPLv2
|
|
# gawk >= 3.1.6: GPLv3
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS += "readline"
|
|
|
|
RDEPENDS_gawk += "gawk-common"
|
|
RDEPENDS_pgawk += "gawk-common"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gawk/gawk-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "4d505dc2c9f1eb3e9f8d6cac87d4bd1a"
|
|
SRC_URI[sha256sum] = "6e0de117c3713aa8d7fa347fc9fd645b10038ae49d8cf947d8c1d51cbb76141a"
|
|
|
|
inherit autotools gettext texinfo update-alternatives
|
|
|
|
PACKAGES += "gawk-common pgawk dgawk"
|
|
|
|
FILES_${PN} = "${bindir}/gawk* ${bindir}/igawk"
|
|
FILES_gawk-common += "${datadir}/awk/* ${libexecdir}/awk/*"
|
|
FILES_pgawk = "${bindir}/pgawk*"
|
|
FILES_${PN}-dbg += "${libexecdir}/awk/.debug"
|
|
FILES_dgawk = "${bindir}/dgawk*"
|
|
|
|
ALTERNATIVE_${PN} = "awk"
|
|
ALTERNATIVE_TARGET[awk] = "${bindir}/gawk"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
do_install_append() {
|
|
# remove the link since we don't package it
|
|
rm ${D}${bindir}/awk
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
mkdir ${D}${PTEST_PATH}/test
|
|
for i in `grep -vE "@|^$|#|Gt-dummy" ${S}/test/Maketests |awk -F: '{print $1}'` Maketests; \
|
|
do cp ${S}/test/$i* ${D}${PTEST_PATH}/test; \
|
|
done
|
|
}
|