mirror of
https://git.yoctoproject.org/poky
synced 2026-02-21 17:09:42 +01:00
d880b69f02
- Rebase existing patches - Drop 0014-configure-remove-dependencies-on-gmp-and-mpfr-when-g.patch which is already in - Correct packaging path to libgprofng.so - Below commits on binutils-2.40 stable branch are updated. 4671be001eb Updated Hungarian translation for the gprof directory ded035f913e lto: Don't add indirect symbols for versioned aliases in IR 74cb2ddeabc gas: arm: Change warning message to not reference specific A-class architecture revision 570b9c09bbf gas: arm: Fix a further IT-predicated vcvt issue in the presense of MVE vcvtn bddd62e188c libctf: get the offsets of fields of unnamed structs/unions right 7aa47eafcce libctf: fix assertion failure with no system qsort_r 165accf0752 coff_get_normalized_symtab bfd_release af35798e957 PR30217, dynamic relocations using local dynamic symbols 18bb604f1e1 PR30198, Assertion and segfault when linking x86_64 elf and coff 34a2b4a0e21 PR30155, ld segfault in _bfd_nearby_section 3d0046f39aa PR30046, power cmpi leads to unknown architecture 5c87fb1d59b ppc32 and "LOAD segment with RWX permissions" 11f5c1ebf14 Updated Serbian translations for gold, gprof and opcodes sub-directories 38e455b1d9a Updated translations for the bfd and gprof directories. b2bc62b7b4e gas: correct symbol name comparison in .startof./.sizeof. handling 17294931e3e configure: remove dependencies on gmp and mpfr when gdb is disabled 1fc096a4c59 Regen config files e1815414077 Pass $JANSSON_LIBS and $ZSTD_LIBS to ld-bootstrap/bootrap.exp 3e888977f16 bpf: fix error conversion from long unsigned int to unsigned int [-Werror=overflow] 65dbb942145 Updated Swedish translation for the binutils sub-directory 27f59ec47a1 RISC-V: make C-extension JAL available again for (32-bit) assembly edd36b26f35 gprofng: PR30043 libgprofng.so.* are installed to a wrong location c6e269febbc gprofng: PR29521 [docs] man pages are not in the release tarball bcea253f5fa toplevel: Makefile.def: add install-strip dependency on libsframe (From OE-Core rev: 5d7389770af6613af4ca8a2d30cc79d494a91075) (From OE-Core rev: dcaf5192599b9474901ab73b66c330a401623fc1) Signed-off-by: Deepthi Hemraj <Deepthi.Hemraj@windriver.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
76 lines
3.0 KiB
BlitzBasic
76 lines
3.0 KiB
BlitzBasic
require binutils.inc
|
|
require binutils-${PV}.inc
|
|
|
|
DEPENDS += "zlib"
|
|
|
|
EXTRA_OECONF += "--with-sysroot=/ \
|
|
--enable-install-libbfd \
|
|
--enable-install-libiberty \
|
|
--enable-shared \
|
|
--with-system-zlib \
|
|
"
|
|
|
|
EXTRA_OEMAKE:append:libc-musl = "\
|
|
gt_cv_func_gnugettext1_libc=yes \
|
|
gt_cv_func_gnugettext2_libc=yes \
|
|
"
|
|
# libcollector/collector.c:547:15: error: no member named '__fprintf_chk' in 'struct CollectorUtilFuncs'
|
|
EXTRA_OECONF:append:toolchain-clang = " --disable-gprofng"
|
|
# | ../../../gprofng/libcollector/../src/collector_module.h:78:13: error: duplicate member 'pwrite'
|
|
# | ../../../gprofng/libcollector/dispatcher.c:578:8: error: 'struct sigevent' has no member named '_sigev_un'
|
|
EXTRA_OECONF:append:libc-musl = " --disable-gprofng"
|
|
|
|
EXTRA_OECONF:class-native = "--enable-targets=all \
|
|
--enable-64-bit-bfd \
|
|
--enable-install-libiberty \
|
|
--enable-install-libbfd \
|
|
--disable-gdb \
|
|
--disable-gdbserver \
|
|
--disable-libdecnumber \
|
|
--disable-readline \
|
|
--disable-sim \
|
|
--disable-werror"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'debuginfod', d)}"
|
|
PACKAGECONFIG[debuginfod] = "--with-debuginfod, --without-debuginfod, elfutils"
|
|
|
|
do_install:class-native () {
|
|
autotools_do_install
|
|
|
|
# Install the libiberty header
|
|
install -d ${D}${includedir}
|
|
install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
|
|
install -m 644 ${S}/include/libiberty.h ${D}${includedir}
|
|
|
|
# We only want libiberty, libbfd and libopcodes
|
|
rm -rf ${D}${bindir}
|
|
rm -rf ${D}${prefix}/${TARGET_SYS}
|
|
rm -rf ${D}${prefix}/lib/ldscripts
|
|
rm -rf ${D}${prefix}/share/info
|
|
rm -rf ${D}${prefix}/share/locale
|
|
rm -rf ${D}${prefix}/share/man
|
|
rmdir ${D}${prefix}/share || :
|
|
rmdir ${D}/${libdir}/gcc-lib || :
|
|
rmdir ${D}/${libdir}64/gcc-lib || :
|
|
rmdir ${D}/${libdir} || :
|
|
rmdir ${D}/${libdir}64 || :
|
|
}
|
|
|
|
# libctf races with libbfd
|
|
PARALLEL_MAKEINST:class-target = ""
|
|
PARALLEL_MAKEINST:class-nativesdk = ""
|
|
|
|
# Split out libbfd-*.so and libopcodes-*.so so including perf doesn't include
|
|
# extra stuff
|
|
PACKAGE_BEFORE_PN += "libbfd libopcodes gprofng"
|
|
FILES:libbfd = "${libdir}/libbfd-*.so.* ${libdir}/libbfd-*.so"
|
|
FILES:libopcodes = "${libdir}/libopcodes-*.so.* ${libdir}/libopcodes-*.so"
|
|
FILES:gprofng = "${sysconfdir}/gprofng.rc ${libdir}/gprofng/libgp-*.so ${libdir}/gprofng/libgprofng.so.* ${bindir}/gp-* ${bindir}/gprofng"
|
|
FILES:${PN}-dev += "${libdir}/libgprofng.so ${libdir}/libsframe.so"
|
|
SRC_URI:append:class-nativesdk = " file://0003-binutils-nativesdk-Search-for-alternative-ld.so.conf.patch "
|
|
|
|
USE_ALTERNATIVES_FOR:class-nativesdk = ""
|
|
FILES:${PN}:append:class-nativesdk = " ${bindir}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|