mirror of
https://git.yoctoproject.org/poky
synced 2026-06-02 18:52:40 +02:00
d96ea299b3
OE-Core commit 8981ed20234c42dc1f5cdef802ebe7214bd55238 (from 2013) caused a regression where -dbg/-dev/-ptest packages weren't generated for packagegroups because we weren't setting ALLOW_EMPTY for them. Break out the code for adding complementary groups to its own conditional so we can set ALLOW_EMPTY at the same time. (From OE-Core rev: 340e9d619c881f320070474d5c4674dcaeabad35) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
2.2 KiB
Plaintext
56 lines
2.2 KiB
Plaintext
# Class for packagegroup (package group) recipes
|
|
|
|
# By default, only the packagegroup package itself is in PACKAGES.
|
|
# -dbg and -dev flavours are handled by the anonfunc below.
|
|
# This means that packagegroup recipes used to build multiple packagegroup
|
|
# packages have to modify PACKAGES after inheriting packagegroup.bbclass.
|
|
PACKAGES = "${PN}"
|
|
|
|
# By default, packagegroup packages do not depend on a certain architecture.
|
|
# Only if dependencies are modified by MACHINE_FEATURES, packages
|
|
# need to be set to MACHINE_ARCH after inheriting packagegroup.bbclass
|
|
PACKAGE_ARCH ?= "all"
|
|
|
|
# Fully expanded - so it applies the overrides as well
|
|
PACKAGE_ARCH_EXPANDED := "${PACKAGE_ARCH}"
|
|
|
|
inherit ${@oe.utils.ifelse(d.getVar('PACKAGE_ARCH_EXPANDED', True) == 'all', 'allarch', '')}
|
|
|
|
# This automatically adds -dbg and -dev flavours of all PACKAGES
|
|
# to the list. Their dependencies (RRECOMMENDS) are handled as usual
|
|
# by package_depchains in a following step.
|
|
# Also mark all packages as ALLOW_EMPTY
|
|
python () {
|
|
packages = d.getVar('PACKAGES', True).split()
|
|
for pkg in packages:
|
|
d.setVar("ALLOW_EMPTY_%s" % pkg, "1")
|
|
if d.getVar('PACKAGEGROUP_DISABLE_COMPLEMENTARY', True) != '1':
|
|
# Add complementary packagegroups
|
|
genpackages = []
|
|
for pkg in packages:
|
|
for postfix in ['-dbg', '-dev', '-ptest']:
|
|
genpackages.append(pkg+postfix)
|
|
d.setVar("ALLOW_EMPTY_%s" % pkg+postfix, "1")
|
|
d.setVar('PACKAGES', ' '.join(packages+genpackages))
|
|
}
|
|
|
|
# We don't want to look at shared library dependencies for the
|
|
# dbg packages
|
|
DEPCHAIN_DBGDEFAULTDEPS = "1"
|
|
|
|
# We only need the packaging tasks - disable the rest
|
|
do_fetch[noexec] = "1"
|
|
do_unpack[noexec] = "1"
|
|
do_patch[noexec] = "1"
|
|
do_configure[noexec] = "1"
|
|
do_compile[noexec] = "1"
|
|
do_install[noexec] = "1"
|
|
do_populate_sysroot[noexec] = "1"
|
|
|
|
python () {
|
|
initman = d.getVar("VIRTUAL-RUNTIME_init_manager", True)
|
|
if initman and initman in ['sysvinit', 'systemd'] and not bb.utils.contains('DISTRO_FEATURES', initman, True, False, d):
|
|
bb.fatal("Please ensure that your setting of VIRTUAL-RUNTIME_init_manager (%s) matches the entries enabled in DISTRO_FEATURES" % initman)
|
|
}
|
|
|